sys-libs/libosinfo: bump to 1.1.0

Package-Manager: Portage-2.3.19, Repoman-2.3.6

sys-libs/libosinfo/Manifest

@@ -1 +1,2 @@
 DIST libosinfo-1.0.0.tar.gz 896212 BLAKE2B 4bd9df9e1aca1b78595bd3f21dda127f46e44ed47a1a82ce83d23dd02fe5d217b5830a808db9cfa658cfa7d8ff5ff4c138c3420e9500255bace4c1a65e7388df SHA512 962b68b2f6639c70b1ab7377475bbddc99a056075e18d1f281e65188eb8a704b932e7ed26362a36ae805d53137e99b0f8303d18a5a1d7b840fad15eb188ab7d0
+DIST libosinfo-1.1.0.tar.gz 904154 BLAKE2B b34d1aaf2d53ac43613cfbdfd05bc12de505d37a743d64e43af379351f640759ad0ec2f30af74bf82a97b3e12b4a02b097bbdd6e0d3e83f7befa2af5340724a2 SHA512 c4f9e67bb5538e31e7d2ed3d764547ba0a2263da5bbf4d1ef930a32d5953fab59abc672e5f86a1f7f5ac1ebd0c5195986193f699a6b0efbcb6769917c0ed7102

sys-libs/libosinfo/libosinfo-1.1.0.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 udev vala
+
+DESCRIPTION="GObject library for managing information about real and virtual OSes"
+HOMEPAGE="http://libosinfo.org/"
+SRC_URI="https://releases.pagure.org/libosinfo/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+
+IUSE="+introspection +vala test"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Unsure about osinfo-db-tools rdep, but at least fedora does it too
+RDEPEND="
+	>=dev-libs/glib-2.36.0:2
+	>=net-libs/libsoup-2.42:2.4
+	>=dev-libs/libxml2-2.6.0
+	>=dev-libs/libxslt-1.0.0
+	sys-apps/hwids[pci,usb]
+	sys-apps/osinfo-db-tools
+	sys-apps/osinfo-db
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
+"
+# perl dep is for pod2man, and configure.ac checks for it too now
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-libs/gobject-introspection-common
+	>=dev-util/gtk-doc-am-1.10
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--with-usb-ids-path=/usr/share/misc/usb.ids \
+		--with-pci-ids-path=/usr/share/misc/pci.ids \
+		--disable-static \
+		$(use_enable test tests) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		--disable-coverage
+}