media-gfx/mypaint: bump to 2.0.1

Bug: https://bugs.gentoo.org/735374
Bug: https://bugs.gentoo.org/708500
Bug: https://bugs.gentoo.org/701098
Closes: https://bugs.gentoo.org/701104
Closes: https://bugs.gentoo.org/701078
Closes: https://bugs.gentoo.org/662562
Package-Manager: Portage-3.0.2, Repoman-2.3.23
Signed-off-by: Sam James <sam@gentoo.org>

media-gfx/mypaint/Manifest

@@ -1 +1,2 @@
 DIST mypaint-1.2.1.tar.xz 37897196 BLAKE2B 2d8f6b03f710febae1c2d617a6e542543786be384585ae8a973604da2eba8a0fb770d185aa3d2dfc6f794adf29ffb9c217356a96ab27d677ebb57816f62fae9c SHA512 1783765e495b9535669a83a29d27ba684e6201fdfe0875bdd2c167b1dab8af05993b19025767fe0b2770ed9e578e4709f75d8a4820ac945812cba85609f9eb9b
+DIST mypaint-2.0.1.tar.xz 7295048 BLAKE2B 813a939f95ea6887c57d8c0868e33e9bc8b1b95746d5ecd793d4fd13a32198ee5a445cfdd2691a15e944bfb0099d6ac624dff320ae29465db5b1e0d197bedb30 SHA512 449beddcc6da5d720c9efbeac94a466ed0057bd1962d42ebb419190e8b7fd8ffd341327408467fc5da47920f9d0da1fd6d78233a0dda88de5f5d52d53d9ab562

media-gfx/mypaint/mypaint-2.0.1.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit desktop distutils-r1 gnome2-utils xdg xdg-utils
+
+DESCRIPTION="fast and easy graphics application for digital painters"
+HOMEPAGE="http://mypaint.org/"
+SRC_URI="https://github.com/mypaint/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+LANGS="cs de en_CA en_GB es fr hu id it ja ko nb nn_NO pl pt_BR ro ru sl sv uk zh_CN zh_TW"
+
+BDEPEND="
+	dev-lang/swig
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		>=dev-python/pycairo-1.4[${PYTHON_USEDEP}]
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
+	')
+	>=dev-libs/json-c-0.11:=
+	gnome-base/librsvg
+	media-gfx/mypaint-brushes:2.0
+	media-libs/lcms:2
+	>=media-libs/libmypaint-1.5.0
+	media-libs/libpng:0=
+	sys-devel/gettext
+	sys-libs/libomp
+	x11-libs/gtk+:3
+"
+DEPEND="${RDEPEND}"
+
+# Need to poke at failing tests
+# Dying on a numpy assert
+RESTRICT="test"
+
+distutils_enable_tests setup.py
+
+src_install() {
+	distutils-r1_src_install
+
+	newicon pixmaps/${PN}_logo.png ${PN}.png
+
+	local lang=
+	for lang in ${LANGS}; do
+		if ! has ${lang} ${LINGUAS}; then
+			rm -rf "${ED}"/usr/share/locale/${lang} || die
+		fi
+	done
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	xdg_mimeinfo_database_update
+}