dev-python/jaraco-envs: New package

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

dev-python/jaraco-envs/Manifest

@@ -0,0 +1 @@
+DIST jaraco-envs-1.0.1.tar.gz 8133 BLAKE2B 05ec6b0ea7532dcf6efe32fe7d1d6a1346d60294ed09743a6f7a47599406bb798f1250525b241aa24b971849f485f89440a56e8ca6b94b2f6847c48aab281be8 SHA512 df5aa3fe06be5091745697cb5f9dda6110fa60e1330515dddbb3e8441eb2232ba1036cfaef7ac8f054958c1a890601330b04b81a0887c4ebc6b41f29335df76b

dev-python/jaraco-envs/jaraco-envs-1.0.1.ebuild

@@ -0,0 +1,39 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit distutils-r1
+
+MY_PN="${PN//-/.}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Classes for orchestrating Python (virtual) environments."
+HOMEPAGE="https://github.com/jaraco/jaraco.envs"
+SRC_URI="https://github.com/jaraco/jaraco.envs/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-python/namespace-jaraco[${PYTHON_USEDEP}]
+	dev-python/path-py[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/contextlib2[${PYTHON_USEDEP}]' 'python3_[67]')"
+BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+
+# there are no actual tests, just flake8 etc
+RESTRICT="test"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# avoid a dep on setuptools_scm
+	sed -i "s:use_scm_version=True:version=\"${PV}\":" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
+	distutils-r1_python_install --skip-build
+}

dev-python/jaraco-envs/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">jaraco.envs</remote-id>
+		<remote-id type="github">jaraco/jaraco.envs</remote-id>
+	</upstream>
+</pkgmetadata>