www-apps/radicale: bump to 3.5.0

Closes: https://github.com/gentoo/gentoo/pull/41151
Signed-off-by: Henning Schild <henning@hennsch.de>
Signed-off-by: Yixun Lan <dlan@gentoo.org>

www-apps/radicale/Manifest

@@ -1,2 +1,3 @@
 DIST Radicale-3.3.1.gh.tar.gz 170518 BLAKE2B 6c0230c94047a234fe1336cc62e4cb5e83639beb093ca02324c1a94f9580c36203089b1a915f9740a00cfa5f7708b7b3a3f252e2d8e7dd2aa85cacff636a4354 SHA512 d5fba7f433c6daedcc033170e33d4bc5ea9279ec6492dc1a966afe148441c4dba6cc762b7ad3181b70a0742b136eebcd4fec7d2438506d60a71d09395dcf20f1
 DIST Radicale-3.4.1.gh.tar.gz 184481 BLAKE2B 87c200466bb7879305ef2b692e9483746fa82c475d85ba552164ab5092c4f08ca9f5b69d2449d1993bd8406ddaf37d9c259556744c37a6c1903a18fdd58c610e SHA512 6907fd696dac25eff85114673f182b6998872d02549147a894cd69654c44a0bec3a51adbf69dacde0c4cd9b7e3005dda8edc6c11f237df514ba3d06508684191
+DIST Radicale-3.5.0.gh.tar.gz 190792 BLAKE2B e0eeb1a9b0c5ce28481cdf3b840fec407a508cb5e38faab8c253cbcc15951f45b87ab4aff3b363fa88f112c2c44038b8fa1aae729145dbbb8837a4f6c65f2eb4 SHA512 00028bc94e4c41c844d24f51259ce8fb831194fd17e5fe29105d484d32c720295a45bb6ff44f9a1c4155b0143df5c0e74cef6eb8f9f48a0650c4cd89832f3620

www-apps/radicale/radicale-3.5.0.ebuild

@@ -0,0 +1,96 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature systemd
+
+MY_P=${P^}
+DESCRIPTION="A simple CalDAV calendar server"
+HOMEPAGE="https://radicale.org/"
+SRC_URI="
+	https://github.com/Kozea/Radicale/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+RDEPEND="
+	>=acct-user/radicale-0-r2
+	acct-group/radicale
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	dev-python/passlib[${PYTHON_USEDEP}]
+	dev-python/vobject[${PYTHON_USEDEP}]
+	sys-apps/util-linux
+"
+
+BDEPEND="
+	test? (
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/waitress[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDIR=/var/lib/"${PN}"
+
+DOCS=( DOCUMENTATION.md CHANGELOG.md )
+
+python_test() {
+	epytest -o addopts= radicale/tests/
+}
+
+python_install_all() {
+	rm README* || die
+	# init file
+	newinitd "${FILESDIR}"/radicale-r4.init.d radicale
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	# directories
+	keepdir "${RDIR}"
+	fperms 0750 "${RDIR}"
+	fowners "${PN}:${PN}" "${RDIR}"
+
+	# config file
+	insinto /etc/"${PN}"
+	doins config
+
+	# fcgi and wsgi files
+	exeinto /usr/share/"${PN}"
+	doexe radicale.wsgi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	local _erdir="${EROOT}${RDIR}"
+
+	ewarn ""
+	ewarn "Since 3.5.0 the default [auth] type is \"denyall\". You need to"
+	ewarn "change your config if you used the deafult type so far!"
+	ewarn ""
+	einfo "A sample WSGI script has been put into ${EROOT}/usr/share/${PN}."
+	einfo "You will also find there an example FastCGI script."
+	if [[ $(stat --format="%U:%G:%a" "${_erdir}") != "${PN}:${PN}:750" ]]
+	then
+		ewarn ""
+		ewarn "Unsafe file permissions detected on ${_erdir}."
+		ewarn "This probably comes from an earlier version of this ebuild."
+		ewarn "To fix run:"
+		ewarn "#  \`chown -R ${PN}:${PN} ${_erdir}\`"
+		ewarn "#  \`chmod 0750 ${_erdir}\`"
+		ewarn "#  \`chmod -R o= ${_erdir}\`"
+	fi
+
+	optfeature "Publish changes to rabbitmq" dev-python/pika
+	optfeature "LDAP/LDAPS authentication" dev-python/ldap3 dev-python/python-ldap
+	optfeature "bcrypt password hashing" dev-python/bcrypt
+}