dev-libs/libwacom: Version bump to 1.9

Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
Matt Turner
2021-03-20 12:27:41 -04:00
parent 3cc2fe57c8
commit 2aefd829c5
2 changed files with 61 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST libwacom-1.1.tar.bz2 502696 BLAKE2B 1c2e03b00eb3b17dea2d5cd3e61afa4b7f36dcb727f07bb1cc42631febc9d1939bdd2652d6fd1f0d020815cac1f937c1daddae3019ac9aa01659442cdc8b9054 SHA512 8b63d9bad18c27f8078711408a7b79c70086cd0c64fe692ee693d53d834dff8ab45631eabd206f0dfac80d8cc86c14b5833831b1b99b06e34aacd235176d266b
DIST libwacom-1.7.tar.bz2 513320 BLAKE2B 36cead331b8d79fa629803441190de2c28e22c0e70822075d0ff31552f780e93d606ec2229a2fee744d9e6b91eb4879cb5a202075caf6adf1301b07502cefb7b SHA512 0cdd34c54a4477ffb763c4a291f0a6b33d2df6b1d237332b116e792685201a63a50c3ec98b84e9dc7c0b97c9e407c3531cd67c0af5a8398b5bbf8be6ca103066
DIST libwacom-1.9.tar.bz2 516223 BLAKE2B 272dd462bee6f152840fb684213d5cdf83cda05b71b95e28a4a307240fa3edcb42b7afb9ef0ac1bd8b470a138e54f3fed9509b02186aff771314fa87ecf3307a SHA512 d62da97038caeaf727800a680a4ef2ef49a56e632844b9a0d6c0eed9c808e033bc1d969aa1c523b4a1724dfb9b8b3665290ecb90fcdcfbf5f50cae2d06c0bffa
+60
View File
@@ -0,0 +1,60 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
inherit meson python-any-r1 toolchain-funcs udev
DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
HOMEPAGE="https://github.com/linuxwacom/libwacom"
SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.bz2"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc test"
RESTRICT="!test? ( test )"
BDEPEND="
virtual/pkgconfig
doc? ( app-doc/doxygen )
test? (
${PYTHON_DEPS}
$(python_gen_any_dep '
dev-python/python-libevdev[${PYTHON_USEDEP}]
dev-python/pyudev[${PYTHON_USEDEP}]
dev-python/pytest[${PYTHON_USEDEP}]
')
)
"
RDEPEND="
dev-libs/glib:2
dev-libs/libgudev:=
"
DEPEND="${RDEPEND}"
python_check_deps() {
has_version -b "dev-python/python-libevdev[${PYTHON_USEDEP}]" &&
has_version -b "dev-python/pyudev[${PYTHON_USEDEP}]" &&
has_version -b "dev-python/pytest[${PYTHON_USEDEP}]"
}
pkg_setup() {
tc-ld-disable-gold # bug https://github.com/linuxwacom/libwacom/issues/170
if use test; then
python-any-r1_pkg_setup
fi
}
src_configure() {
local emesonargs=(
$(meson_feature doc documentation)
$(meson_feature test tests)
-Dudev-dir=$(get_udevdir)
)
meson_src_configure
}