app-admin/bitwarden-desktop-bin: add 2025.8.2

Signed-off-by: Yixun Lan <dlan@gentoo.org>

app-admin/bitwarden-desktop-bin/Manifest

@@ -1,2 +1,3 @@
 DIST Bitwarden-2025.7.0-amd64.deb 88607466 BLAKE2B 87abfc416029173b4483c8a0e23530e3accaecaaa62238558a95fc54244d8ac7a36be1ccca5a051a35c48c3b4180d14e2cf1c87b46ee84463850264c55a7b0b5 SHA512 b0a324a063106b0a5e36716b3a351ac74a260dddf44383a1abbc617ef55918242dc0fc79b86dde47545af18a4407cc4b1d0252ebc5320748e5455e6b897cccaa
 DIST Bitwarden-2025.8.1-amd64.deb 88590908 BLAKE2B 50b43da5f8c9b421b4c087a826ef23c86d741e75e9adbc7542e8839ea5087d20ab9dbe349a5125210f341192665d7cf28546bde9030ba1c7e77fb4b2a0c12392 SHA512 0e2cecda55873b8560ff7c5edf5b06c84896d849de364b93a42b159c303a07c1038aaca1305cb311a33b083d5e32edb9ed55a587f54ebe1e3b8e937d485a2b4c
+DIST Bitwarden-2025.8.2-amd64.deb 88581450 BLAKE2B 02430f4c8396ba31e1967d393ab0a3e45306467cb7162b0b9df78aa91b205240567331b7b3c90b6f9a07091287d1db71207a3941522b2b54b4749962f40684e1 SHA512 199314ce463cb2c9409322fd8d916e4043f211c436bcc4eb3845a283328630732676fef4cc2b7f6d8e548d5cddddef09d30da683f88290c3a28e5d6d33494f8c

app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-2025.8.2.ebuild

@@ -0,0 +1,90 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker xdg-utils
+
+DESCRIPTION="Bitwarden password manager desktop client"
+HOMEPAGE="https://bitwarden.com/"
+SRC_URI="https://github.com/bitwarden/clients/releases/download/desktop-v${PV}/Bitwarden-${PV}-amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret
+	dev-libs/expat
+	dev-libs/glib
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libxshmfence
+	x11-libs/libXtst
+	x11-libs/pango
+"
+IDEPEND="
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+"
+
+QA_PREBUILT="
+	opt/Bitwarden/*.so*
+	opt/Bitwarden/bitwarden
+	opt/Bitwarden/bitwarden-app
+	opt/Bitwarden/chrome-sandbox
+	opt/Bitwarden/chrome_crashpad_handler
+	opt/Bitwarden/desktop_proxy
+"
+
+src_install() {
+	insinto /opt
+	doins -r opt/Bitwarden
+	fperms 755 /opt/Bitwarden/bitwarden \
+		/opt/Bitwarden/bitwarden-app
+	fperms 4755 /opt/Bitwarden/chrome-sandbox
+
+	domenu usr/share/applications/bitwarden.desktop
+
+	local x
+	for x in 16 32 64 128 256 512; do
+		doicon -s ${x} usr/share/icons/hicolor/${x}*/*
+	done
+
+	dosym -r "/opt/Bitwarden/bitwarden" "usr/bin/${PN}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}