sci-libs/indilib: add 2.1.2

Closes: https://bugs.gentoo.org/939098
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

sci-libs/indilib/Manifest

@@ -1 +1,2 @@
 DIST indilib-2.1.1.tar.gz 2929685 BLAKE2B 565199451a2ebbf6757bb854e0dad576397a6154c6043543243364b6072375afd775ed0b54ed116b2702bdea222b47e4f68673da617e68ebf626d1725e66d2a7 SHA512 3224afb13776462e906398be2b85802807e739042494b29701d106731423640a4dceaeb262cd62d3a87f032ba0655da7ceaa150e6912be20508e090ad93c3ba7
+DIST indilib-2.1.2.tar.gz 2940192 BLAKE2B 61a8f73cb5d7561852db0e63f7332eed7f0ea65279c05fe3c13e8891acaae81fe60c86da78ee0eeea1adc6a183065bd92af519493087c6959a29a3fae84107b5 SHA512 77838f7b64443f68a0aa6f0bc0232fbacaeed3d0759bc16496f11e434cf6d3eb2cb5ae07f49b1fa200c9dadc91e9418f6f5ea8f593e03543719a2d73ddb061d2

sci-libs/indilib/indilib-2.1.2.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="ogg rtlsdr test websocket"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/cpp-httplib:=
+	dev-cpp/nlohmann_json
+	dev-libs/libev
+	media-libs/libjpeg-turbo:=
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	sys-libs/zlib
+	virtual/libusb:1
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora
+	)
+	rtlsdr? ( net-wireless/rtl-sdr )
+	websocket? ( dev-libs/boost:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+	websocket? ( dev-cpp/websocketpp )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_SYSTEM_HTTPLIB=ON
+		-DINDI_SYSTEM_JSONLIB=ON
+		-DINDI_BUILD_QT5_CLIENT=OFF
+		-DINDI_BUILD_SHARED=ON
+		-DINDI_BUILD_STATIC=OFF
+		-DINDI_BUILD_XISF=OFF # not packaged
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_INTEGTESTS=$(usex test)
+		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Unit tests
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+
+	# Integration tests
+	# They fail in parallel because they try to bind to the same port more
+	# than once.
+	BUILD_DIR="${BUILD_DIR}"/integs cmake_src_test -j1
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}