mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
app-i18n/opencc: Version bump (1.0.6).
Signed-off-by: Arfrever Frehtes Taifersar Arahesis <Arfrever@Apache.Org> Signed-off-by: Mike Gilbert <floppym@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST opencc-1.0.5.tar.gz 1598354 BLAKE2B a66b32b96dab543d8401960ff0548a4e3f9414606513941426eacf105bca0755a7b364c68b7eb996ef82444e52f849d2f8151353a14fb97a358ad1463fbea2d3 SHA512 3fbefbafe5c3c2491032158577ab97b5a3edf6ea98a03a7250deba082b72c3112ad4a3396d1a469936ec32e1d141f0a2236001c2891ac9c793add2b082596cc1
|
||||
DIST opencc-1.0.6.tar.gz 1621561 BLAKE2B d58ee0e04e133fbf6a7632788bcaf0f7891bb74051a970075f6d94b048adfec7bbe4438913933d7dfdd4d58ec2c1a5ec47685415c26532ddd8c13e8abd52cab6 SHA512 67c7bb7432483c1781701dc64ff28e4d5750898ed3d2d41f97d3782918b5f9aa1a49baa1e3a58e4b24cfbd2adcf9ea166a05ad934221fb1cb7afb35e909749e7
|
||||
|
||||
@@ -0,0 +1,63 @@
|
||||
# Copyright 2010-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="7"
|
||||
PYTHON_COMPAT=(python{3_7,3_8,3_9})
|
||||
|
||||
inherit cmake python-any-r1
|
||||
|
||||
if [[ "${PV}" == "9999" ]]; then
|
||||
inherit git-r3
|
||||
|
||||
EGIT_REPO_URI="https://github.com/BYVoid/OpenCC"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Library for conversion between Traditional and Simplified Chinese characters"
|
||||
HOMEPAGE="https://github.com/BYVoid/OpenCC"
|
||||
if [[ "${PV}" == "9999" ]]; then
|
||||
SRC_URI=""
|
||||
else
|
||||
SRC_URI="https://github.com/BYVoid/OpenCC/archive/ver.${PV}.tar.gz -> ${P}.tar.gz"
|
||||
fi
|
||||
|
||||
# OpenCC: Apache-2.0
|
||||
# deps/darts-clone: BSD-2
|
||||
# deps/gtest-1.7.0: BSD
|
||||
# deps/rapidjson-0.11: MIT
|
||||
# deps/tclap-1.2.1: MIT
|
||||
LICENSE="Apache-2.0 BSD-2 MIT test? ( BSD )"
|
||||
SLOT="0/2"
|
||||
KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
|
||||
IUSE="doc test"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
BDEPEND="${PYTHON_DEPS}
|
||||
doc? ( app-doc/doxygen )"
|
||||
DEPEND=""
|
||||
RDEPEND=""
|
||||
|
||||
if [[ "${PV}" != "9999" ]]; then
|
||||
S="${WORKDIR}/OpenCC-ver.${PV}"
|
||||
fi
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-stop-copy.patch"
|
||||
)
|
||||
|
||||
DOCS=(AUTHORS NEWS.md README.md)
|
||||
|
||||
src_prepare() {
|
||||
cmake_src_prepare
|
||||
|
||||
sed -e "s:\${DIR_SHARE_OPENCC}/doc:share/doc/${PF}:" -i doc/CMakeLists.txt || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_DOCUMENTATION=$(usex doc ON OFF)
|
||||
-DBUILD_SHARED_LIBS=ON
|
||||
-DENABLE_GTEST=$(usex test ON OFF)
|
||||
)
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
Reference in New Issue
Block a user