dev-python/jupyter-server: Bump to 2.13.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/jupyter-server/Manifest

@@ -1 +1,2 @@
 DIST jupyter_server-2.12.5.tar.gz 713833 BLAKE2B f6e133a5f778d2abe9971a94db9c033fbfba587fc6265dbeed20f903cb1f1007b53f263c5674945e324dd15879e77ffab03f94c236d4ddbde00179af7ae71f94 SHA512 dd4fee86cfe82641dc9bbab2de93f65b45e78d56fad6d0a5ecdc442a4facc93aecbe90516200fa742f13d83039119640279efd4c42ff53a08786671c79d4a268
+DIST jupyter_server-2.13.0.tar.gz 718244 BLAKE2B 578e67c6f3cc94c167c27b59e6ef3a5c7dc69048731da9480b2a4021fa52a16cce02d97d4986f5cb739cafd4041b183ccff1a4fa5b22e0cca6e46cdb9d101e86 SHA512 114387c34bf759bc9d27eedf2cb2ab12c07ddaec33d0d37c3bcaa776058c028220dc148fd7bc270644192a693b613b54d0195b5b809c2732c1e04d551b4d060c

dev-python/jupyter-server/jupyter-server-2.13.0.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter-server/jupyter_server/
+	https://pypi.org/project/jupyter-server/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-7.4.4[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-5.1.0[${PYTHON_USEDEP}]
+	dev-python/jupyter-server-terminals[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-events-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-6.4.4[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.3.0[${PYTHON_USEDEP}]
+	dev-python/overrides[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/prometheus-client[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24[${PYTHON_USEDEP}]
+	>=dev-python/send2trash-1.8.2[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.2[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.6.0[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+
+"
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		>=dev-python/pytest-jupyter-0.7[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# This fails if your terminal is zsh (and maybe other non-bash as well?)
+		tests/test_terminal.py
+		# Fails because above is ignored
+		tests/auth/test_authorizer.py
+		# Fails with additional extensions installed
+		tests/extension/test_app.py::test_stop_extension
+	)
+
+	# FIXME: tests seem to be affected by previously installed version
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest \
+		-p pytest_tornasync.plugin \
+		-p jupyter_server.pytest_plugin \
+		-p pytest_console_scripts \
+		-p pytest_timeout \
+		-o tmp_path_retention_policy=all
+}