dev-libs/wayland: Version bump to 1.24.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-libs/wayland/Manifest

@@ -1 +1,2 @@
 DIST wayland-1.23.1.tar.xz 238212 BLAKE2B 74784b537a6e28610466ff1549286cea9ff8b9ca914afa26a07f177bbe0be56b80de037d5eb5d07a38bf02a9041c32e62c896facd5417c1435571640ad8f87b2 SHA512 818eda003e3f7aa15690eedb1ff227a6056b2ce54bf23d45ffe573dc40a914623c5a1358218b59444dcdc483db0503324f0d27091d0ea954412a8b290de5f50a
+DIST wayland-1.24.0.tar.xz 241764 BLAKE2B 7ac6ac1f33cb2cae60e4058478655eeabd4f8f8e0fe07f6b9b386967ed4b31bdaac571dc2b812f3189534e3e53797822ca39f829207e45c24b494f039f82a836 SHA512 60216602cffd1473ae15381f9e9a6f3829e742cac83843ca65360ba78bcff8d9442f15eb6a6d5d29c8f74dd920762ca1605f51658d22a1d3c18e338505b9f974

dev-libs/wayland/wayland-1.24.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/wayland/wayland.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitlab.freedesktop.org/wayland/${PN}/-/releases/${PV}/downloads/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+inherit meson-multilib
+
+DESCRIPTION="Wayland protocol libraries"
+HOMEPAGE="https://wayland.freedesktop.org/ https://gitlab.freedesktop.org/wayland/wayland"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	~dev-util/wayland-scanner-${PV}
+	virtual/pkgconfig
+	doc? (
+		>=app-text/doxygen-1.6[dot]
+		app-text/xmlto
+		>=media-gfx/graphviz-2.26.0
+	)
+"
+DEPEND="
+	>=dev-libs/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_bool doc documentation)
+		$(meson_native_true dtd_validation)
+		-Dlibraries=true
+		-Dscanner=false
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# We set it on purpose to only a short subdir name, as socket paths are
+	# created in there, which are 108 byte limited. With this it hopefully
+	# barely fits to the limit with /var/tmp/portage/${CATEGORY}/${PF}/temp/x
+	export XDG_RUNTIME_DIR="${T}"/x
+	mkdir "${XDG_RUNTIME_DIR}" || die
+	chmod 0700 "${XDG_RUNTIME_DIR}" || die
+
+	multilib-minimal_src_test
+}
+
+src_install() {
+	meson-multilib_src_install
+
+	if use doc; then
+		mv "${ED}"/usr/share/doc/"${PN}"/* "${ED}"/usr/share/doc/"${PF}"/ || die
+		rmdir "${ED}"/usr/share/doc/"${PN}" || die
+	fi
+}