kde-apps/cantor: drop 26.08.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/cantor/Manifest

@@ -1,3 +1,2 @@
 DIST cantor-26.04.3.tar.xz 10921248 BLAKE2B 900314d9fbd7bdadbe3e98a83727e00c6954bd5c4fbf23807a3c64852226777b1d0207d5fd68c504fe027b16f8bcd41a3fa75b174505c621b97796b065c1ecb0 SHA512 243a989e23ac9798ff44e670781233efa2ec5e83afa29419a9ddfc4f087c6af79994b78f57ca9ef803ccc68ea175de114e501c5ef5f6c644d9e5d1ca0f203e5b
-DIST cantor-26.08.0.tar.xz 10922960 BLAKE2B 03864cf52f9cac7e89b2c8a4b08f9ef1c2b08162bf06e0f4c35105956f5ce0d3016b610be139403500522e49449530a478072b34f64e122242ee113d8ce53808 SHA512 066cb9bd9107b86d78e5ac1292c0cfd74e9e56ec960fc59bf9ff253b743db04ff0500abcfedbb61103876008808b10b0ff546bcb1d7f18d7dd6e1994f450f4fb
 DIST cantor-26.08.1.tar.xz 10922880 BLAKE2B d65aaf31b0b2e9d2ee1a7f43b07cb9ee1e9c4df2665987bee7de54defdab685ae9d5617ca4865a5af9d00fae470b20ff9ce56da267d626bef72539e6a89bf9d9 SHA512 80e76741b0d764d7c79ad1323a0b00cd22b3c4b510a9747ebc0abd8407f04253f083b305619a65dcc11a6bd31a15f130c497f9371d9ee270c096845fc795169f

kde-apps/cantor/cantor-26.08.0.ebuild

@@ -1,113 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CMAKE_MAKEFILE_GENERATOR="emake"
-CMAKE_QA_COMPAT_SKIP=1 # bug 965858
-ECM_HANDBOOK="optional"
-ECM_TEST="forceoptional"
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{12..15} )
-PVCUT=$(ver_cut 1-3)
-KFMIN=6.27.0
-QTMIN=6.11.2
-inherit ecm gear.kde.org lua-single optfeature python-single-r1 xdg
-
-DESCRIPTION="Interface for doing mathematics and scientific computing"
-HOMEPAGE="https://apps.kde.org/cantor/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="6"
-KEYWORDS="~amd64 ~arm64"
-IUSE="+analitza julia lua postscript python qalculate R webengine"
-
-REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} ) python? ( ${PYTHON_REQUIRED_USE} )"
-RESTRICT="test"
-
-# TODO Add Sage Mathematics Software backend (https://www.sagemath.org)
-DEPEND="
-	>=app-text/poppler-23.12.0[qt6]
-	dev-libs/libxml2:2=
-	dev-libs/libxslt
-	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets,xml]
-	>=dev-qt/qtsvg-${QTMIN}:6
-	>=kde-frameworks/karchive-${KFMIN}:6
-	>=kde-frameworks/kcompletion-${KFMIN}:6
-	>=kde-frameworks/kconfig-${KFMIN}:6
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
-	>=kde-frameworks/kcoreaddons-${KFMIN}:6
-	>=kde-frameworks/kcrash-${KFMIN}:6
-	>=kde-frameworks/ki18n-${KFMIN}:6
-	>=kde-frameworks/kiconthemes-${KFMIN}:6
-	>=kde-frameworks/kio-${KFMIN}:6
-	>=kde-frameworks/knewstuff-${KFMIN}:6
-	>=kde-frameworks/kparts-${KFMIN}:6
-	>=kde-frameworks/ktexteditor-${KFMIN}:6
-	>=kde-frameworks/ktextwidgets-${KFMIN}:6
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
-	>=kde-frameworks/kxmlgui-${KFMIN}:6
-	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
-	analitza? ( >=kde-apps/analitza-${PVCUT}:6 )
-	julia? ( dev-lang/julia-bin:* )
-	lua? ( ${LUA_DEPS} )
-	qalculate? (
-		sci-libs/cln
-		sci-libs/libqalculate:=
-	)
-	python? (
-		${PYTHON_DEPS}
-		>=dev-qt/qtbase-${QTMIN}:6[dbus]
-	)
-	R? ( dev-lang/R )
-	webengine? (
-		>=dev-qt/qttools-${QTMIN}:6[assistant]
-		>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
-	)
-"
-# !analitza?
-RDEPEND="${DEPEND}
-	!analitza? ( !julia? ( !lua? ( !python? ( !qalculate? ( !R? (
-		|| (
-			sci-mathematics/maxima
-			sci-mathematics/octave
-		)
-	) ) ) ) ) )
-"
-BDEPEND="x11-misc/shared-mime-info"
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-	use python && python-single-r1_pkg_setup
-}
-
-src_configure() {
-	if use julia; then
-		addpredict /proc/self/mem # bug 602894
-		addpredict /proc/self/fd # bug 909435
-	fi
-
-	local mycmakeargs=(
-		$(cmake_use_find_package analitza Analitza6)
-		$(cmake_use_find_package julia Julia)
-		$(cmake_use_find_package lua LuaJIT)
-		$(cmake_use_find_package python Python3)
-		$(cmake_use_find_package qalculate Qalculate)
-		$(cmake_use_find_package R R)
-		-DENABLE_EMBEDDED_DOCUMENTATION=$(usex webengine)
-	)
-	use lua && mycmakeargs+=(
-		-DLUAJIT_INCLUDEDIR="${EPREFIX}/$(lua_get_include_dir)"
-		-DLUAJIT_LIBDIR="${EPREFIX}/$(lua_get_cmod_dir)"
-	)
-	ecm_src_configure
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Maxima backend" sci-mathematics/maxima
-		optfeature "Octave backend" sci-mathematics/octave
-		optfeature "LaTeX support" virtual/latex-base
-	fi
-	xdg_pkg_postinst
-}