gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-util/vulkan-tools: Make sure NDEBUG is set

Browse Source 
Bug: https://bugs.gentoo.org/796662
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>
This commit is contained in:
Nick Sarnie
2021-08-07 15:35:35 -04:00
parent f417aa0799
commit 296a7e3ebc
2 changed files with 96 additions and 5 deletions
Download Patch File Download Diff File Expand all files Collapse all files

86
dev-util/vulkan-tools/vulkan-tools-1.2.182-r1.ebuild Normal file
View File

@@ -0,0 +1,86 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
MY_PN=Vulkan-Tools
CMAKE_ECLASS="cmake-utils"
CMAKE_MAKEFILE_GENERATOR="emake"
PYTHON_COMPAT=( python3_{8,9} )
inherit cmake-multilib python-any-r1
if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
EGIT_SUBMODULES=()
inherit git-r3
else
SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv"
S="${WORKDIR}"/${MY_PN}-${PV}
fi
DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
LICENSE="Apache-2.0"
SLOT="0"
IUSE="cube wayland +X"
# Cube demo only supports one window system at a time
REQUIRED_USE="cube? ( ^^ ( X wayland ) )"
BDEPEND="${PYTHON_DEPS}
>=dev-util/cmake-3.10.2
cube? ( dev-util/glslang:=[${MULTILIB_USEDEP}] )
"
RDEPEND="
>=media-libs/vulkan-loader-${PV}:=[${MULTILIB_USEDEP},wayland?,X?]
wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
X? (
x11-libs/libX11:=[${MULTILIB_USEDEP}]
x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
)
"
DEPEND="${RDEPEND}
>=dev-util/vulkan-headers-${PV}
"
pkg_setup() {
MULTILIB_CHOST_TOOLS=(
/usr/bin/vulkaninfo
)
use cube && MULTILIB_CHOST_TOOLS+=(
/usr/bin/vkcube
/usr/bin/vkcubepp
)
python-any-r1_pkg_setup
}
src_prepare() {
cmake-utils_src_prepare
}
multilib_src_configure() {
local mycmakeargs=(
-DCMAKE_SKIP_RPATH=ON
-DBUILD_VULKANINFO=ON
-DBUILD_CUBE=$(usex cube)
-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
-DBUILD_WSI_XCB_SUPPORT=$(usex X)
-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
)
use cube && mycmakeargs+=(
-DGLSLANG_INSTALL_DIR="${ESYSROOT}/usr"
-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
)
cmake-utils_src_configure
}
multilib_src_install() {
cmake-utils_src_install
}

15
dev-util/vulkan-tools/vulkan-tools-9999.ebuild
View File

@@ -4,8 +4,9 @@
EAPI=7
MY_PN=Vulkan-Tools
CMAKE_ECLASS="cmake"
PYTHON_COMPAT=( python3_{7,8,9} )
CMAKE_ECLASS="cmake-utils"
CMAKE_MAKEFILE_GENERATOR="emake"
PYTHON_COMPAT=( python3_{8,9} )
inherit cmake-multilib python-any-r1
if [[ ${PV} == *9999* ]]; then
@@ -14,7 +15,7 @@ if [[ ${PV} == *9999* ]]; then
inherit git-r3
else
SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv"
S="${WORKDIR}"/${MY_PN}-${PV}
fi
@@ -57,6 +58,10 @@ pkg_setup() {
python-any-r1_pkg_setup
}
src_prepare() {
cmake-utils_src_prepare
}
multilib_src_configure() {
local mycmakeargs=(
-DCMAKE_SKIP_RPATH=ON
@@ -73,9 +78,9 @@ multilib_src_configure() {
-DCUBE_WSI_SELECTION=$(usex X XCB WAYLAND)
)
cmake_src_configure
cmake-utils_src_configure
}
multilib_src_install() {
cmake_src_install
cmake-utils_src_install
}