app-emulation/punes: update to 0.105 (#696616)

Closes: https://bugs.gentoo.org/696616
Signed-off-by: Azamat H. Hackimov <azamat.hackimov@gmail.com>
Package-Manager: Portage-2.3.66, Repoman-2.3.16
Closes: https://github.com/gentoo/gentoo/pull/12687
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

app-emulation/punes/Manifest

@@ -1 +1,2 @@
 DIST punes-0.104.tar.gz 5381182 BLAKE2B fefa6eb85e9cfe5eb10fd987061e6f708a2d29db374552ca217e1e47bfd3a982390d2fdf33f23407bb54d7e1a3491e33cc2c520ff3ead4566f687c6c652bcc6a SHA512 9636440cf66cb9f48b532cebff4342a775ddacffd98748e5669d820e213a648cbfb3e4e94f67389f21f88b4fa618bf514e31738c10df079abe22d4b19593d904
+DIST punes-0.105.tar.gz 5376203 BLAKE2B 9008ee14189d669c4c4c815de1c5498e3af22cbae52a25b538ae658fdc3fe9d39600a431e6652c84b24e20b1e713847462e4b802021a635c8f14f7d91317678f SHA512 4ce1487554218b17b0e3e2966c7b4ac0852e0b0bc83aeabbb0e3127d4952f0ef921374a97ce59990d01b5e0ac08204cca5f13476cd7e4a1e7a238850e8305d29

app-emulation/punes/punes-0.105.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg-utils
+
+DESCRIPTION="Nintendo Entertainment System (NES) emulator"
+HOMEPAGE="https://github.com/punesemu/puNES"
+SRC_URI="https://github.com/punesemu/puNES/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cg"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-libs/alsa-lib
+	virtual/opengl"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	cg? ( media-gfx/nvidia-cg-toolkit )
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig"
+
+S="${WORKDIR}/puNES-${PV}"
+
+src_prepare() {
+	default
+
+	sed -i "/update-desktop-database/d" misc/Makefile.am || die
+	eautoreconf
+	# FIXME why eautoreconf can't handle this?
+	cd "src/extra/lib7zip-1.6.5" || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with cg opengl-nvidia-cg)
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}