dev-util/sysdig: Bump to 0.26.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-util/sysdig/Manifest

@@ -1,2 +1,3 @@
 DIST sysdig-0.26.1.tar.gz 892441 BLAKE2B 38302458c54a10719fadaf5e5bb6d29931a262550eaf44350543e99cd33e6a90889d81f49096d2f57fcc903bc9245a1f782b438a48613f9fc9f90273c46f0f39 SHA512 817573dd2945e20094c548a481205d7ae700e8242a12c75bcab41c52330fb6f508214d71f3d3ba4ecc86576e555c8c2a0c155921d61d29a5861bbf982600f6fb
 DIST sysdig-0.26.2.tar.gz 907496 BLAKE2B ce489d7c1a54aa2930599aa7141b1a3d4815c0395b4a444dea565334a1b39a36d339eb2bc9d0c2b3924e8c54f9c3adec6b31278017cfee955fe9ed9d3c29977f SHA512 1a2476060f43559ec89663377361d1fcaace7fe3aa3b472629dca78557e6d5868d8f5cfce3411c46804b501d6a56dcb074f6becf3d8e756b7f7fd943087cd3ae
+DIST sysdig-0.26.3.tar.gz 902206 BLAKE2B ec25d0441c69b8c4c4fc431d073d2f93e476ece7add98412e54ce4286bcd7e32d4b1ff89f75dd728dc66c7d77da157bed2182bad85557c0dcec09648f86abb3d SHA512 f700d1ddae687a3474a8bf6816d2fef6c69e963a269a90a8362287dee698ac9799da18f01f383368c906d294ceb046160a8b0792292a72a3b08fc614b5b69d32

dev-util/sysdig/sysdig-0.26.3.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MODULES_OPTIONAL_USE=modules
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0
+	modules? ( || ( MIT GPL-2 ) )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-cpp/tbb:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	dev-libs/protobuf:0=
+	net-dns/c-ares:0=
+	net-libs/grpc:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS ~TRACEPOINTS"
+
+pkg_pretend() {
+	linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${BUILD_DIR}/driver/src:)"
+	BUILD_PARAMS='KERNELDIR="${KERNEL_DIR}"'
+	BUILD_TARGETS="all"
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+	linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED}"/usr/etc || die
+}