mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 17:09:10 -07:00
media-gfx/darktable: add 4.4.2
Signed-off-by: Marek Szuba <marecki@gentoo.org>
This commit is contained in:
Marek Szuba
@@ -1,5 +1,6 @@
|
||||
DIST darktable-4.2.1.tar.xz 6112480 BLAKE2B bf6f60b1f01b16c7cc4ffae7fbb46c7d2ce465d6fafd507564b8dd20aeadb3cd1116e434214d07c9c53ca621228ea6f7ce75a01650d04d596d1e246789bae752 SHA512 05423c16ff813c10fa2bedbb22bbc886f2cff81aad2493c720f4b2fe32ba89b55c428287cd1c4b24cc98121d441375752015f88c30f796ea46db18461e212d5d
|
||||
DIST darktable-4.4.1.tar.xz 5956860 BLAKE2B 429086161c56005f902565509525d84a86fb54d318584c4ce8c2da65ea23bebf5772440a5f4cfa023f4738526b2b19c5055257702b2ae1f49349a77462ccd78d SHA512 20af12232957416693515745d28e49351c8e2c20a5c0ea4b11672167aa8521b5377cdbd17fad1a258d97aad0e9f31f55b9f86c816e613e91ef1910edc7d71099
|
||||
DIST darktable-4.4.2.tar.xz 6033932 BLAKE2B 99fec3b3ebc80a03af068d9a9a27a1cbd601183a15d52129495e1bb924be03d274cb768a34ec8c6ad432946f46a78a5d2ba325ae133a82988d828c2170f70991 SHA512 7b87879e865001491bbeaa12b9ac42b006bfa3fbcb50e73384c76cce0ee5d87200be3ce9b11f56d669d5eaf9b1add0a018ec5a021653bb84dfb6a0b379cb5594
|
||||
DIST darktable-usermanual-4.2.en.pdf 26559897 BLAKE2B 144b7e76567e92138c7e75c996a63f818dce7eb4f485f0d988d184874d2ee2a72e89efae1d0fb16bc25aac831da040ffbd4a7bbda08d8c750169f06668a98f88 SHA512 a23e9544026d9aff7b92b3ca874217ebc12e1dc876e9d7873e0e7e61a53090179a1377cc4409f2bb8f6d005133e4501ce444c1533c8d66f04b7cc0c5fc5a3531
|
||||
DIST darktable-usermanual-4.2.uk.pdf 26454596 BLAKE2B e497c87903f85ae7ebb9b9624124ba19936869db6d19d229182e5d249938f5d9461435ac7ae15f9a2fd64b367aa712ac1de5f32d053cc08a99a3bd672e8cac0b SHA512 ba37d680f29d2d79f517360a1b43d88b49cf5810b638aa5bc6eeeb8016bd1634801119c2d283473bafc72920db2525b122815fa475bac0c41a6cc8d2ac579a61
|
||||
DIST darktable-usermanual-4.4.en.pdf 34311705 BLAKE2B 98094ed8288be092ec9c0398bf1719992ce80723aa803e3924e9d28c1c5f2717b120ed618cbec6eebb958be59d15fe107428099efd87926622b5d08110e36b67 SHA512 90e8b8912776b674a436a7e2377d16b0ef374d879ba16501a1c8a0c8407776ef362b747121859884e0aac1d9fc94f3bf0a58bbccdc6fce27cbcaf4cf169d6ef3
|
||||
|
||||
192
media-gfx/darktable/darktable-4.4.2.ebuild
Normal file
192
media-gfx/darktable/darktable-4.4.2.ebuild
Normal file
@@ -0,0 +1,192 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
LUA_COMPAT=( lua5-4 )
|
||||
|
||||
inherit cmake flag-o-matic lua-single toolchain-funcs xdg
|
||||
|
||||
DESCRIPTION="A virtual lighttable and darkroom for photographers"
|
||||
HOMEPAGE="https://www.darktable.org/"
|
||||
LICENSE="GPL-3 CC-BY-3.0"
|
||||
SLOT="0"
|
||||
|
||||
if [[ ${PV} == *9999 ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/darktable-org/${PN}.git"
|
||||
|
||||
LANGS=" af ca cs da de el es fi fr gl he hu it ja nb nl pl pt-BR pt-PT ro ru sk sl sq sv th uk zh-CN zh-TW"
|
||||
else
|
||||
DOC_PV=$(ver_cut 1-2)
|
||||
MY_PV="${PV/_/}"
|
||||
MY_P="${P/_/.}"
|
||||
|
||||
SRC_URI="https://github.com/darktable-org/${PN}/releases/download/release-${MY_PV}/${MY_P}.tar.xz
|
||||
doc? (
|
||||
https://docs.darktable.org/usermanual/${DOC_PV}/en/${PN}_user_manual.pdf -> ${PN}-usermanual-${DOC_PV}.en.pdf
|
||||
l10n_uk? (
|
||||
https://docs.darktable.org/usermanual/${DOC_PV}/uk/${PN}_user_manual.pdf
|
||||
-> ${PN}-usermanual-${DOC_PV}.uk.pdf
|
||||
)
|
||||
)"
|
||||
|
||||
KEYWORDS="~amd64 ~arm64 -x86"
|
||||
LANGS=" de es fr he hu ja pl pt-BR sl sq uk zh-CN zh-TW"
|
||||
fi
|
||||
|
||||
IUSE="avif colord cpu_flags_x86_avx cpu_flags_x86_sse3 cups doc gamepad geolocation gmic keyring gphoto2 graphicsmagick heif jpeg2k jpegxl kwallet lto lua midi nls opencl openmp openexr test tools webp
|
||||
${LANGS// / l10n_}"
|
||||
|
||||
REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
|
||||
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
# It is sometimes requested, by both users and certain devs, to have sys-devel/gcc[graphite]
|
||||
# in BDEPEND. This has not been done *on purpose*, for the following reason:
|
||||
# - darktable can also be built with sys-devel/clang so we'd have to have that, as an alternative,
|
||||
# in BDEPEND too
|
||||
# - there are at least two darktable dependencies (media-libs/mesa and virtual/rust) which
|
||||
# by default pull in sys-devel/clang
|
||||
# - as a result of the above, for most gcc users adding the above to BDEPEND is a no-op
|
||||
# (and curiously enough, empirical observations suggest current versions of Portage are
|
||||
# more likely to pull in Clang to build darktable with than to request enabling USE=graphite
|
||||
# on GCC; that might be a bug though)
|
||||
BDEPEND="dev-util/intltool
|
||||
virtual/pkgconfig
|
||||
nls? ( sys-devel/gettext )
|
||||
test? ( >=dev-python/jsonschema-3.2.0 )"
|
||||
DEPEND="dev-db/sqlite:3
|
||||
dev-libs/icu:=
|
||||
dev-libs/json-glib
|
||||
dev-libs/libxml2:2
|
||||
>=dev-libs/pugixml-1.8:=
|
||||
gnome-base/librsvg:2
|
||||
>=media-gfx/exiv2-0.25-r2:=[xmp]
|
||||
media-libs/lcms:2
|
||||
>=media-libs/lensfun-0.2.3:=
|
||||
media-libs/libjpeg-turbo:=
|
||||
media-libs/libpng:=
|
||||
media-libs/tiff:=
|
||||
net-libs/libsoup:2.4
|
||||
net-misc/curl
|
||||
sys-libs/zlib:=
|
||||
x11-libs/cairo
|
||||
>=x11-libs/gtk+-3.22:3
|
||||
x11-libs/pango
|
||||
avif? ( >=media-libs/libavif-0.8.2:= )
|
||||
colord? ( x11-libs/colord-gtk:= )
|
||||
cups? ( net-print/cups )
|
||||
gamepad? ( media-libs/libsdl2 )
|
||||
geolocation? ( >=sci-geosciences/osm-gps-map-1.1.0 )
|
||||
gmic? ( media-gfx/gmic )
|
||||
keyring? ( >=app-crypt/libsecret-0.18 )
|
||||
gphoto2? ( media-libs/libgphoto2:= )
|
||||
graphicsmagick? ( media-gfx/graphicsmagick )
|
||||
heif? ( media-libs/libheif:= )
|
||||
jpeg2k? ( media-libs/openjpeg:2= )
|
||||
jpegxl? ( media-libs/libjxl:= )
|
||||
lua? ( ${LUA_DEPS} )
|
||||
midi? ( media-libs/portmidi )
|
||||
opencl? ( virtual/opencl )
|
||||
openexr? ( media-libs/openexr:= )
|
||||
webp? ( media-libs/libwebp:= )"
|
||||
RDEPEND="${DEPEND}
|
||||
kwallet? ( >=kde-frameworks/kwallet-5.34.0-r1 )"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-3.4.0_jsonschema-automagic.patch
|
||||
"${FILESDIR}"/${PN}-3.4.1_libxcf-cmake.patch
|
||||
"${FILESDIR}"/${PN}-4.2.1_cmake-musl.patch
|
||||
)
|
||||
|
||||
S="${WORKDIR}/${P/_/~}"
|
||||
|
||||
pkg_pretend() {
|
||||
if [[ ${MERGE_TYPE} != binary ]]; then
|
||||
# Bug #695658
|
||||
if tc-is-gcc; then
|
||||
if ! test-flags-CC -floop-block &> /dev/null; then
|
||||
eerror "Building ${PN} with GCC requires Graphite support."
|
||||
eerror "Please switch to a version of sys-devel/gcc built with USE=graphite, or use a different compiler."
|
||||
die "Selected compiler is sys-devel/gcc[-graphite]"
|
||||
fi
|
||||
fi
|
||||
|
||||
use openmp && tc-check-openmp
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
|
||||
use lua && lua-single_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
use cpu_flags_x86_avx && append-flags -mavx
|
||||
use cpu_flags_x86_sse3 && append-flags -msse3
|
||||
|
||||
sed -i -e 's:/appdata:/metainfo:g' data/CMakeLists.txt || die
|
||||
|
||||
cmake_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_CURVE_TOOLS=$(usex tools)
|
||||
-DBUILD_NOISE_TOOLS=$(usex tools)
|
||||
-DBUILD_PRINT=$(usex cups)
|
||||
-DCUSTOM_CFLAGS=ON
|
||||
-DDONT_USE_INTERNAL_LUA=ON
|
||||
-DRAWSPEED_ENABLE_LTO=$(usex lto)
|
||||
-DRAWSPEED_ENABLE_WERROR=OFF
|
||||
-DRAWSPEED_MUSL_SYSTEM=$(usex elibc_musl)
|
||||
-DTESTBUILD_OPENCL_PROGRAMS=OFF
|
||||
-DUSE_AVIF=$(usex avif)
|
||||
-DUSE_CAMERA_SUPPORT=$(usex gphoto2)
|
||||
-DUSE_COLORD=$(usex colord)
|
||||
-DUSE_GMIC=$(usex gmic)
|
||||
-DUSE_GRAPHICSMAGICK=$(usex graphicsmagick)
|
||||
-DUSE_JXL=$(usex jpegxl)
|
||||
-DUSE_KWALLET=$(usex kwallet)
|
||||
-DUSE_LIBSECRET=$(usex keyring)
|
||||
-DUSE_LUA=$(usex lua)
|
||||
-DUSE_MAP=$(usex geolocation)
|
||||
-DUSE_NLS=$(usex nls)
|
||||
-DUSE_OPENCL=$(usex opencl)
|
||||
-DUSE_OPENEXR=$(usex openexr)
|
||||
-DUSE_OPENJPEG=$(usex jpeg2k)
|
||||
-DUSE_OPENMP=$(usex openmp)
|
||||
-DUSE_PORTMIDI=$(usex midi)
|
||||
-DUSE_SDL2=$(usex gamepad)
|
||||
-DUSE_WEBP=$(usex webp)
|
||||
-DWANT_JSON_VALIDATION=$(usex test)
|
||||
)
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake_src_install
|
||||
# This USE flag is masked for -9999
|
||||
use doc && dodoc "${DISTDIR}"/${PN}-usermanual-${DOC_PV}.*.pdf
|
||||
|
||||
if use nls; then
|
||||
for lang in ${LANGS} ; do
|
||||
if ! use l10n_${lang}; then
|
||||
rm -r "${ED}"/usr/share/locale/${lang/-/_} || die
|
||||
fi
|
||||
done
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
elog
|
||||
elog "When updating a major version,"
|
||||
elog "please bear in mind that your edits will be preserved during this process,"
|
||||
elog "but it will not be possible to downgrade any more."
|
||||
elog
|
||||
ewarn "It will not be possible to downgrade!"
|
||||
ewarn
|
||||
}
|
||||
Reference in New Issue
Block a user