gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

media-video/mediainfo: version bump to 0.7.83

Browse Source
This commit is contained in:
Tim Harder
2016-03-05 21:21:23 -05:00
parent 335528cbea
commit 27e783f4ec
2 changed files with 73 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
media-video/mediainfo/Manifest
View File

@@ -2,3 +2,4 @@ DIST mediainfo_0.7.73.tar.bz2 1467006 SHA256 a7cae29ac45a642c6747746db150382ed88
DIST mediainfo_0.7.80.tar.xz 1293796 SHA256 2030a3075111c78282579c15eea8e5215717f19a8014490045d157b6098f3c8a SHA512 1ffaf931a21fa8cbd15a67d033d60a22b2ecba24870740d7a241f130303cca883c9df7b333b860a0a4a6ff6647418b4eb142cfbb97d4aad7725f5ad2ebbf7384 WHIRLPOOL b072a42564387860c5179f43e1233abb2406e0e21446f1a9391bdc5ca21fc8ab534cc15b38ddb4aa79ccdb79c976256db2edbad2852433aa64c9959fbc7e1003
DIST mediainfo_0.7.81.tar.xz 1295940 SHA256 077c9eb3471ec8a8160d154047692b001b09877bcd9bea18c4f0413c894750a9 SHA512 7ca2fccd62096ed4924ccc9bdac799a33252121ef8c634dfbbf6e547da151a4549aadf82335091d471c911c026b65ceb9bfc9d4c75dafff12c91e1fd0c41e107 WHIRLPOOL 08c87a80ce6bbd14b1060c3087834ac278ad7ff53cfb8510b313e91c16657c49c399a8f3891b692c502bdb1151fff840a502a7e948d2d249fbb8c320a5b4be37
DIST mediainfo_0.7.82.tar.xz 1297504 SHA256 62882c977f209c0a4e2cb47f2109180fbe6b5337e471a3eb728daa917aaf7b47 SHA512 d07bd35d2b6fdff5ebb6546d294362d597001625f5a6c74d987629304b58d3f20e7c750d586ca6bfb1e05f8fb1b93dbadf4799721ec777a6c03f35232a4bdc80 WHIRLPOOL 59da6119a4f610fc1416da0d443a8242dcb316b6360e120f797b1efac34587e1819b22fa39531debe257f74d0ccb8f2b2f1fb803037a485b3525ddf1a88b37a4
DIST mediainfo_0.7.83.tar.xz 1298048 SHA256 e7f95f54640532666949c1fe9c305259c705f1048a86c718e054bc4513bc1535 SHA512 b453d9312fd09b650d704120e18b7c379b8cb2ad58995f89381da3a3ca9e1885a5d4286658595ff1828ccee9c3c72b5e20486bcba9ec17d760cd8eb8144c2c66 WHIRLPOOL 4f06b90e191e5ed6247a7db46ebd69ebedf4e7a648a3268ee2ee2ef9f473b52fa88293efc8de110671f8e418961a8812aca2c6317c470f6e201d763a37b612a2

72
media-video/mediainfo/mediainfo-0.7.83.ebuild Normal file
View File

@@ -0,0 +1,72 @@
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
WX_GTK_VER="3.0"
inherit eutils autotools wxwidgets multilib
DESCRIPTION="MediaInfo supplies technical and tag information about media files"
HOMEPAGE="http://mediaarea.net/mediainfo/"
SRC_URI="http://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl mms wxwidgets"
RDEPEND="sys-libs/zlib
media-libs/libzen
~media-libs/lib${P}[curl=,mms=]
wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
DEPEND="${RDEPEND}
virtual/pkgconfig"
S=${WORKDIR}/MediaInfo
pkg_setup() {
TARGETS="CLI"
use wxwidgets && TARGETS+=" GUI"
}
src_prepare() {
epatch_user
local target
for target in ${TARGETS}; do
cd "${S}"/Project/GNU/${target}
sed -i -e "s:-O2::" configure.ac
eautoreconf
done
}
src_configure() {
local target
for target in ${TARGETS}; do
cd "${S}"/Project/GNU/${target}
local args=""
[[ ${target} == "GUI" ]] && args="--with-wxwidgets --with-wx-gui"
econf ${args}
done
}
src_compile() {
local target
for target in ${TARGETS}; do
cd "${S}"/Project/GNU/${target}
default
done
}
src_install() {
local target
for target in ${TARGETS}; do
cd "${S}"/Project/GNU/${target}
default
dodoc "${S}"/History_${target}.txt
if [[ ${target} == "GUI" ]]; then
newicon "${S}"/Source/Resource/Image/MediaInfo.png ${PN}.png
make_desktop_entry ${PN}-gui MediaInfo ${PN} "AudioVideo;GTK"
fi
done
}