media-video/subtitleeditor: Apply Debian patchset

This fixes some bugs like metainfo location and porting to enchant-2

Closes: https://bugs.gentoo.org/782103
Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

media-video/subtitleeditor/Manifest

@@ -1 +1,2 @@
 DIST subtitleeditor-0.54.0.tar.gz 1783077 BLAKE2B a802124c9b81ad5fecc4914b6231e7efaf3326f231115f334fd53b79d8a851bf2f09fdccdee85c53b0cc828fe67c72e9924f47f0881d0438e563b18b1f77f00b SHA512 4458d579775a504b22f955c41d0e95ed722c1cb6bcf715ef493988a85397d5e0d4c3327e129f49b160d398dc73257026a92bbe5104c30d2004c16b7e12dd113c
+DIST subtitleeditor_0.54.0-5.debian.tar.xz 9100 BLAKE2B 249048228aab601524bb1f6e222863d1d3f96e3be4a05e08196a164d0e4ed3ff4b662fbac5a468a546f871e314a99f68ed9132692a5be8997d8338810ab91808 SHA512 9e15c0f6d4ddc88650f6f7962b09175fddbae1c1ac295a83c33e29e1212f09a1d88711a4e1250c5f125d72ea02f4b77c3ca9f62594ee0010f0cf8d383fbe0832

media-video/subtitleeditor/subtitleeditor-0.54.0_p5.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GNOME2_EAUTORECONF="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit flag-o-matic gnome2
+
+DESCRIPTION="GTK+3 subtitle editing tool"
+HOMEPAGE="https://kitone.github.io/subtitleeditor"
+SRC_URI="https://github.com/kitone/${PN}/releases/download/${PV}/${P/_p*}.tar.gz
+	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV/_p*}-${PV/*_p}.debian.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug nls"
+# opengl would mix gtk+:2 and :3 which is not possible
+
+RDEPEND="
+	>=app-text/enchant-2.2.0:2
+	app-text/iso-codes
+	>=dev-cpp/cairomm-1.12:0
+	>=dev-cpp/glibmm-2.46:2
+	>=dev-cpp/gtkmm-3.18:3.0
+	>=dev-cpp/gstreamermm-1.0:1.0=
+	>=dev-cpp/libxmlpp-2.40:2.6
+	dev-libs/glib:2
+	>=dev-libs/libsigc++-2.6:2
+	media-libs/gst-plugins-base:1.0[X,pango]
+	media-libs/gst-plugins-good:1.0
+	media-libs/gstreamer:1.0
+	media-plugins/gst-plugins-meta:1.0
+	x11-libs/gtk+:3
+	nls? ( virtual/libintl )
+"
+#	opengl? (
+#		>=dev-cpp/gtkglextmm-1.2.0-r2:1.0
+#		virtual/opengl )
+# X needed for video output and pango needed for text overlay
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${P/_p*}"
+
+PATCHES=(
+	# https://github.com/kitone/subtitleeditor/issues/49
+	"${FILESDIR}"/${PN}-0.52.1-disable-nls-fix.patch
+)
+
+src_prepare() {
+	# Debian patches
+	for p in $(<"${WORKDIR}"/debian/patches/series) ; do
+		eapply -p1 "${WORKDIR}/debian/patches/${p}"
+	done
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Avoid using --enable-debug as it mocks with CXXFLAGS and LDFLAGS
+	use debug && append-cxxflags -DDEBUG
+
+	gnome2_src_configure \
+		--disable-debug \
+		--disable-gl \
+		$(use_enable nls)
+#		$(use_enable opengl gl)
+}