kde-apps/dolphin: 26.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2026-07-02 19:05:32 +02:00
parent 26fa56f704
commit 276a7e29d1
2 changed files with 92 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST dolphin-26.04.1.tar.xz 5894652 BLAKE2B 2eb9589929862ea555d8aaf3dcd72fdcfd8a066cd9626ec025b9e55ef51ec5ae4572fbdb0cce10223a75f3e67e54182a1d3ee4c562f38d3dab2a2f1eaae4cfb1 SHA512 dec15ebe3d9112b15239cfc30094364cc9367c5ce246064cce080d563c31af209963c8cb60232be317728272d077671648c2ddc311308bdb403ecb404c0d29e6
DIST dolphin-26.04.2.tar.xz 5896240 BLAKE2B 020ece0e12861da1b2493ded2297f1f8f5feab9a4c69c22f5f2342d5ae9c3cc6263cace64c67ac3d41313a95fa171cee9ba1280d702222292587c804aeed7f6b SHA512 06140c8b0f25c11d481487803c7591104aa78bd1d86ae557caa9582a8df57ffeb01c0d865306abf2e90214898d183ced1eacf642a69f5c3b8c47e7903ece0c64
DIST dolphin-26.04.3.tar.xz 5896212 BLAKE2B 2d4d8d812312324106ac3563d3c4ec66539cb2b7da95aef56f574e42f95daf194f68865ccae24265a35445182305422654744ec6947d7525767d67ef86d65e17 SHA512 724772f1a93456d05feed3c6edbfae6422c7c25b71a48fa60382f49ec55c3c8286ceb7aafffd22570b0e9dd4c9adaff7342c6c058788506561d8abc71d2daa97
+91
View File
@@ -0,0 +1,91 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="true"
PVCUT=$(ver_cut 1-3)
KFMIN=6.23.0
QTMIN=6.10.1
inherit ecm gear.kde.org optfeature xdg
DESCRIPTION="Plasma filemanager focusing on usability"
HOMEPAGE="https://apps.kde.org/dolphin/ https://userbase.kde.org/Dolphin"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="semantic-desktop telemetry"
# slot op: Uses Qt::GuiPrivate for qtx11extras_p.h
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6=[concurrent,dbus,gui,widgets,X,xml]
>=dev-qt/qtmultimedia-${QTMIN}:6
>=kde-frameworks/kbookmarks-${KFMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kcodecs-${KFMIN}:6
>=kde-frameworks/kcolorscheme-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kfilemetadata-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6=
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knewstuff-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
semantic-desktop? (
>=kde-apps/baloo-widgets-${PVCUT}:6
>=kde-frameworks/baloo-${KFMIN}:6
)
telemetry? ( >=kde-frameworks/kuserfeedback-${KFMIN}:6 )
"
RDEPEND="${DEPEND}
>=kde-apps/kio-extras-${PVCUT}:6
>=kde-apps/thumbnailers-${PVCUT}:6
"
CMAKE_SKIP_TESTS=(
servicemenuinstaller # requires ruby, no thanks
dolphinmainwindowtest # hangs forever
kfileitem{listview,model}test # hang forever
kitemlistcontrollertest # hangs forever
kitemlistcontrollerexpandtest # flaky even according to upstream # bug 947223
placesitemmodeltest # requires DBus
)
src_configure() {
local mycmakeargs=(
-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt6=ON
$(cmake_use_find_package semantic-desktop KF6Baloo)
$(cmake_use_find_package semantic-desktop KF6BalooWidgets)
$(cmake_use_find_package telemetry KF6UserFeedback)
)
use test && mycmakeargs+=(
-DCMAKE_DISABLE_FIND_PACKAGE_SeleniumWebDriverATSPI=ON # not packaged
)
ecm_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "compress/extract and other actions" "kde-apps/ark:${SLOT}"
optfeature "crypto actions" "kde-apps/kleopatra:${SLOT}"
optfeature "'Share' context menu actions" "kde-frameworks/purpose:${SLOT}"
fi
xdg_pkg_postinst
}