net-dns/pdns: Version bump

Signed-off-by: Sven Wegener <swegener@gentoo.org>
Package-Manager: Portage-2.3.66, Repoman-2.3.11
This commit is contained in:
Sven Wegener
2019-05-30 10:44:33 +00:00
parent 1c0010578d
commit 26dc7801d1
2 changed files with 155 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST pdns-4.1.7.tar.bz2 1116191 BLAKE2B 8c214bff6d1af8354dc0b22c2bed233ec92e217fcfda456f69a665eb615500452f2bea7abfbab506f93abc35d0466a26594734a242e5cfef2b62e789252274d1 SHA512 dc9c693ac2eaf11ddce220e7fedc40f6ae3f9d7a55352643b30db2aad0b2d543ad04a14199a06355275aba2d9dd7873087715a16157b0ff2f7335f1a4a4b96a2
DIST pdns-4.1.8.tar.bz2 1116996 BLAKE2B df32e1e239f65a37570b1f3f6b7fd2384ea9ea4d60ecf6dc520441e7f004c9e17c1cb35358e1cd9b5080c85b6366354ae4b3e5eaeda20af18c6e411bb119bbc1 SHA512 1113745cdaa8fba591c176721893fb478e976861beee0cb6c0240e5afa6b68c9afae286579036b2ed77fffe76ca1e6f103cda915f8b7b875bcdc1253931ad935
DIST pdns-4.2.0-rc1.tar.bz2 1221177 BLAKE2B fa911805bfe9c04ffe6b508e1deec716e9149a6cfe10b771bb8bb214c4b4db72a9d4990eb21145e13422388c48563e2951c6e7d210a59dc2d3569cac6a3232b8 SHA512 bd769a2e0159b44d5699b0166d20afe49d9c48aa04c170405099a897417a12887a4dfb54bf9c100498be37a519c91e08a96039b23bdbc1cf33499ea63841c1ba
+154
View File
@@ -0,0 +1,154 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
inherit multilib user
DESCRIPTION="The PowerDNS Daemon"
HOMEPAGE="https://www.powerdns.com/"
SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="" # ~amd64 ~x86
# other possible flags:
# db2: we lack the dep
# oracle: dito (need Oracle Client Libraries)
# xdb: (almost) dead, surely not supported
IUSE="debug doc geoip ldap libressl lua luajit mydns mysql opendbx postgres protobuf remote sodium sqlite systemd tools tinydns test"
REQUIRED_USE="mydns? ( mysql )"
RDEPEND="
libressl? ( dev-libs/libressl:= )
!libressl? ( dev-libs/openssl:= )
>=dev-libs/boost-1.35:=
lua? (
!luajit? ( dev-lang/lua:= )
luajit? ( dev-lang/luajit:= )
)
mysql? ( dev-db/mysql-connector-c )
postgres? ( dev-db/postgresql:= )
ldap? ( >=net-nds/openldap-2.0.27-r4 app-crypt/mit-krb5 )
sqlite? ( dev-db/sqlite:3 )
opendbx? ( dev-db/opendbx )
geoip? ( >=dev-cpp/yaml-cpp-0.5.1:= dev-libs/geoip )
sodium? ( dev-libs/libsodium:= )
tinydns? ( >=dev-db/tinycdb-0.77 )
protobuf? ( dev-libs/protobuf )"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig
doc? ( app-doc/doxygen )"
S="${WORKDIR}"/${P/_/-}
src_configure() {
local dynmodules="pipe bind" # the default backends, always enabled
#use db2 && dynmodules+=" db2"
use ldap && dynmodules+=" ldap"
use lua && dynmodules+=" lua"
use mydns && dynmodules+=" mydns"
use mysql && dynmodules+=" gmysql"
use opendbx && dynmodules+=" opendbx"
#use oracle && dynmodules+=" goracle oracle"
use postgres && dynmodules+=" gpgsql"
use remote && dynmodules+=" remote"
use sqlite && dynmodules+=" gsqlite3"
use tinydns && dynmodules+=" tinydns"
use geoip && dynmodules+=" geoip"
#use xdb && dynmodules+=" xdb"
econf \
--disable-static \
--sysconfdir=/etc/powerdns \
--libdir=/usr/$(get_libdir)/powerdns \
--with-modules= \
--with-dynmodules="${dynmodules}" \
--with-mysql-lib=/usr/$(get_libdir) \
$(use_enable debug verbose-logging) \
$(use_enable test unit-tests) \
$(use_enable tools) \
$(use_enable systemd) \
$(use_with sodium libsodium) \
$(use_with lua lua $(usex luajit luajit lua)) \
$(use_with protobuf) \
${myconf}
}
src_compile() {
default
use doc && emake -C codedocs codedocs
}
src_install() {
default
mv "${D}"/etc/powerdns/pdns.conf{-dist,}
fperms 0700 /etc/powerdns
fperms 0600 /etc/powerdns/pdns.conf
# set defaults: setuid=pdns, setgid=pdns
sed -i \
-e 's/^# set\([ug]\)id=$/set\1id=pdns/g' \
"${D}"/etc/powerdns/pdns.conf
newinitd "${FILESDIR}"/pdns-r1 pdns
keepdir /var/empty
if use doc; then
docinto html
dodoc -r codedocs/html/.
fi
# Install development headers
insinto /usr/include/pdns
doins pdns/*.hh
insinto /usr/include/pdns/backends/gsql
doins pdns/backends/gsql/*.hh
if use ldap ; then
insinto /etc/openldap/schema
doins "${FILESDIR}"/dnsdomain2.schema
fi
find "${D}" -name '*.la' -delete || die
}
pkg_preinst() {
enewgroup pdns
enewuser pdns -1 -1 /var/empty pdns
}
pkg_postinst() {
elog "PowerDNS provides multiple instances support. You can create more instances"
elog "by symlinking the pdns init script to another name."
elog
elog "The name must be in the format pdns.<suffix> and PowerDNS will use the"
elog "/etc/powerdns/pdns-<suffix>.conf configuration file instead of the default."
if use ldap ; then
ewarn "The official LDAP backend module is only compile-tested by upstream."
ewarn "Try net-dns/pdns-ldap-backend if you have problems with it."
fi
local old
for old in ${REPLACING_VERSIONS}; do
ver_test ${old} -lt 3.2 || continue
ewarn "To fix a security bug (bug #458018) had the following"
ewarn "files/directories the world-readable bit removed (if set):"
ewarn " ${EPREFIX}/etc/powerdns"
ewarn " ${EPREFIX}/etc/powerdns/pdns.conf"
ewarn "Check if this is correct for your setup"
ewarn "This is a one-time change and will not happen on subsequent updates."
chmod o-rwx "${EPREFIX}"/etc/powerdns/{,pdns.conf}
break
done
}