dev-python/clickdc: new package, add 0.1.1

Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/731
Signed-off-by: Sam James <sam@gentoo.org>

dev-python/clickdc/Manifest

@@ -0,0 +1 @@
+DIST clickdc-0.1.1.tar.gz 10128 BLAKE2B 98d9cf5f223be841c07698ec3a42f8cf49b8808d8090a7a5aaa2809c44d613f87e81fa2cee99e1cb611f8b0b691faaa9fd9de9fa71fb85e17e4845409bd44621 SHA512 9b369d86240da16cc38edae7b7ca705610c8afce3240fafeb287053b860c40cd30bd3af48a73fb5d4444cb62ecb1266c505f817f231671b95d0413fb416e7a6c

dev-python/clickdc/clickdc-0.1.1.ebuild

@@ -0,0 +1,49 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Define click command line options from a python dataclass"
+HOMEPAGE="
+	https://github.com/Kamilcuk/clickdc
+	https://pypi.org/project/clickdc/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pydantic[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Irrevelant downstream, unpackaged pyright
+	"tests/test_typing.py"
+)
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/clickdc-0.1.1-click-8.2.patch
+)
+
+python_prepare_all() {
+	# workaround setuptools-git-versioning
+	sed -e "/^\[project\]/aversion = \"${PV}\"" \
+		-e '/^dynamic =/ s/"version", //' \
+		-i pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}

dev-python/clickdc/files/clickdc-0.1.1-click-8.2.patch

@@ -0,0 +1,15 @@
+More complicated patch
+https://github.com/Kamilcuk/clickdc/pull/3
+
+--- a/tests/test.py
++++ b/tests/test.py
+@@ -11,7 +11,7 @@ import clickdc
+ 
+ 
+ def invoke(*args, **kwargs):
+-    return CliRunner(mix_stderr=True).invoke(*args, **kwargs)
++    return CliRunner().invoke(*args, **kwargs)
+ 
+ 
+ def run(arg_class, input: str, output: Any = None, fail: int = 0, toargs: bool = False):
+

dev-python/clickdc/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">Kamilcuk/clickdc</remote-id>
+		<remote-id type="pypi">clickdc</remote-id>
+	</upstream>
+</pkgmetadata>