dev-util/selenium-manager: Bump to 4.24.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-util/selenium-manager/Manifest

@@ -1,2 +1,4 @@
 DIST selenium-manager-4.23.0-crates.tar.xz 26763004 BLAKE2B b7f584637ae436f0c867ecaef2a04ba4a58178bdffce6f15a702bb6d254368303f7b2d9c1b50e950717deffc8ffe3bbbfc92ff14cd8f472f00387e4c114e924d SHA512 1dd54ae66b7ae93cb061c538140c64062b9185d18801fc759c67945792d59f2c3033f7173216d78f0b493db0000b4efd5cdb0e405b6f7aa242f5fa2472f88811
+DIST selenium-manager-4.24.0-crates.tar.xz 27591764 BLAKE2B 42c120a77df5c48b840200772d3d49aa88c0cbfec67244d13435037631a8f0d67d03249031da44cfc6ecddfb8cd9b90b879df0be896a072141d98f772933aeab SHA512 93943e9cfc54f7e66fc25290c67bb6eee679de5c1a8c1af23c8e79d0ce15aaec4de8a38b8b2346c632ac8e93446cb8c5e37767ba955a3aa5850ad6f4dfdec340
 DIST selenium-selenium-4.23.0.gh.tar.gz 77114209 BLAKE2B ce8b2be71c4bcf83eed5e16d4770f8aa9075cd29c69ab5a019c763e65f1417094bb9e97a2d5ce5bbc773029e187ab3dee4e8296bbef1bbec580e2935b1c8f258 SHA512 0ef7bdba5a1d592e6e9adadd6e3cb0da4949822c61b2787f6d3f282f615f1de692ff775b0ea3e3f179736a685a8543bf6e4790c1a03932ccfe5933719a2bb9a3
+DIST selenium-selenium-4.24.0.gh.tar.gz 77126013 BLAKE2B a909714b93b0cfc92a9d70d8cf20609eec65ebce3470fe487a23c86ac4f6f3dbf2e2ef88e00883999fe8b5e2842a05039fec94f6617961c436649baa618c59f8 SHA512 bc6f8066efba5a4f5a27abcc37eefa303e9efd89423729fedb4f466d98ed57e68c8593248206e4fc13cebd3446fa25a5a856d5f4c1d05940d73cecc920b4c522

dev-util/selenium-manager/selenium-manager-4.24.0.ebuild

@@ -0,0 +1,89 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+
+inherit cargo
+
+TAG=selenium-${PV}
+MY_P=selenium-${TAG}
+DESCRIPTION="CLI tool that manages the browser/driver infrastructure required by Selenium"
+HOMEPAGE="
+	https://www.selenium.dev/
+	https://github.com/SeleniumHQ/selenium/
+"
+SRC_URI="
+	https://github.com/SeleniumHQ/selenium/archive/selenium-${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	SRC_URI+="
+		https://dev.gentoo.org/~mgorny/dist/${P}-crates.tar.xz
+	"
+fi
+S="${WORKDIR}/${MY_P}/rust"
+
+LICENSE="Apache-2.0"
+# Dependent crate licenses
+LICENSE+=" Apache-2.0 BSD ISC MIT MPL-2.0 Unicode-DFS-2016"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~riscv ~x86"
+IUSE="telemetry test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		|| (
+			www-client/firefox
+			www-client/firefox-bin
+		)
+	)
+"
+
+QA_FLAGS_IGNORED="usr/bin/${PN}"
+
+src_prepare() {
+	default
+
+	sed -i -e '/strip/d' Cargo.toml || die
+	if ! use telemetry; then
+		sed -i -e '/avoid-stats/s:false:true:' src/config.rs || die
+	fi
+
+	# Avoid tests requiring Internet or specific browsers (or trying
+	# to fetch them, whatever).
+	rm tests/browser_download_tests.rs || die
+	rm tests/exec_driver_tests.rs || die
+	rm tests/grid_tests.rs || die
+	rm tests/browser_tests.rs || die
+	rm tests/config_tests.rs || die
+	rm tests/iexplorer_tests.rs || die
+	rm tests/mirror_tests.rs || die
+	rm tests/stable_browser_tests.rs || die
+	rm tests/webview_tests.rs || die
+}
+
+src_test() {
+	local -x PATH=${T}/bin:${PATH}
+
+	mkdir "${T}/bin" || die
+	if ! has_version "www-client/firefox"; then
+		# upstream expects "firefox" rather than "firefox-bin"
+		ln -s "$(type -P firefox-bin)" "${T}/bin/firefox" || die
+	fi
+
+	cargo_src_test --no-fail-fast
+}
+
+src_install() {
+	cargo_src_install
+	einstalldocs
+	dodoc README.md
+
+	newenvd - 70selenium-manager <<-EOF || die
+		SE_MANAGER_PATH="${EPREFIX}/usr/bin/selenium-manager"
+	EOF
+}