app-arch/xarchiver: Bump to 0.5.4.15

Closes: https://bugs.gentoo.org/726430
Signed-off-by: Michał Górny <mgorny@gentoo.org>

app-arch/xarchiver/Manifest

@@ -1 +1,2 @@
 DIST xarchiver-0.5.4.14.tar.gz 1081542 BLAKE2B 591d93dfbaa98164bc169105462155b09ed87dab8ad5adff6653e77673095a29d7f00cdaeed1b928039fe3cc5f668f8da46885905ae73d03f5b4c71dd279a7b4 SHA512 b38881e6cdfb402499efbd18ab25cac3869cd48ef96941a4bb3cb8b6b130a2317abe3b1d11bfc3d60e81eef7cafa34515fefc11e469443d96d139c2f09cf4498
+DIST xarchiver-0.5.4.15.tar.gz 1072943 BLAKE2B 6f80c8dba510bf5c05dfe5c8f12aafbd4f563861878c73b7da78562836ef4b85f9bc8e4ed7cda5d98c5e33a211a2677d163c2912f1bb605e0085627ca4ee5cbb SHA512 e5174241dd45dd6186d91b15a15b207a8b356480d9ce1a7b9ac2da167878cdb14316a3e7abf3f2aac8d41a02777df2131e205c7d5971a376ff7dd0ca70fbc82f

app-arch/xarchiver/xarchiver-0.5.4.15.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg-utils
+
+DESCRIPTION="A GTK+ archive manager that can be used with Thunar"
+HOMEPAGE="https://github.com/ib/xarchiver"
+SRC_URI="https://github.com/ib/xarchiver/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+# older pigz versions have incompatible command-line processing
+# https://bugs.gentoo.org/661464
+RDEPEND=">=dev-libs/glib-2:=
+	x11-libs/gtk+:3=
+	!!<app-arch/pigz-2.4[symlink]"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/docbook-xml-dtd
+		app-text/docbook-xsl-stylesheets
+		dev-libs/libxml2
+		dev-libs/libxslt
+	)"
+
+src_prepare() {
+	sed -e '/COPYING/d' -e '/NEWS/d' -i doc/Makefile.am || die
+	default
+	mkdir m4 || die
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable doc)
+	)
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+
+	elog "You need external programs for some formats, including:"
+	elog "7zip - app-arch/p7zip"
+	elog "arj - app-arch/unarj app-arch/arj"
+	elog "lha - app-arch/lha"
+	elog "lzop - app-arch/lzop"
+	elog "rar - app-arch/unrar app-arch/rar"
+	elog "zip - app-arch/unzip app-arch/zip"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}