net-libs/dleyna: Version bump to 0.8.3

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/33130
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

net-libs/dleyna/Manifest

@@ -1 +1,2 @@
 DIST dLeyna-v0.8.2.tar.bz2 149691 BLAKE2B c9837da15c18b25c0e9021776cabdcffe52acfaac0f2858ab004b554d9a212ca45cc08f2893383248c5bb5ce57df854d79c329f80511b9f098663326f1badecc SHA512 25a62ad6b623a8d67d90af608d0fa68e4dcef916c5b44f51eb927f6e276555b978414c95f59a680c5938c7b67abe0cc09afa4e58d068f115d73ce6cb40959144
+DIST dLeyna-v0.8.3.tar.bz2 149796 BLAKE2B e1fc2d1d5fa6178856d5114b55dbaae5a969ab7f2b5716ab70c1359755b21927ed0ecfd8d943520254a1ead2b2db368838787f0954bc312712a8075ea3f94896 SHA512 a62c643467b2f75efb9e794802b3bc183a5f8cfe9b80eeaee627aeaa471d7fb107cf1bde549c274ecd86ca06ad5870a481316e1101647c9d7e6243114b5dd06e

net-libs/dleyna/dleyna-0.8.3.ebuild

@@ -0,0 +1,54 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1
+
+DESCRIPTION="A set of services and D-Bus APIs to simplify access to UPnP/DLNA media devices"
+HOMEPAGE="https://gitlab.gnome.org/World/dLeyna"
+SRC_URI="https://gitlab.gnome.org/World/dLeyna/-/archive/v${PV}/dLeyna-v${PV}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="1.0/6" # soname of libdleyna-core-1.0.so
+KEYWORDS="~amd64 ~loong ~riscv ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	>=dev-libs/glib-2.28:2
+	>=net-libs/gssdp-1.6.0:1.6=
+	>=net-libs/gupnp-1.6.0:1.6=
+	>=net-libs/gupnp-av-0.12.9:0=
+	>=media-libs/gupnp-dlna-0.9.4:2.0=
+	>=net-libs/libsoup-3.0:3.0
+	dev-libs/libxml2
+
+	${PYTHON_DEPS}
+
+	!net-libs/dleyna-connector-dbus
+	!net-libs/dleyna-core
+	!net-libs/dleyna-renderer
+	!net-misc/dleyna-server
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/docutils
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}"/dLeyna-v${PV}
+
+src_configure() {
+	local emesonargs=(
+		-Ddbus_service_dir="${EPREFIX}/usr/share/dbus-1/services"
+		-Dman_pages=true
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}