dev-ada/gprbuild: Enable compilation with gnat-gpl-2019

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

dev-ada/gprbuild/gprbuild-2018-r4.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs multiprocessing
+
+MYP=${PN}-gpl-${PV}
+
+DESCRIPTION="Multi-Language Management"
+HOMEPAGE="http://libre.adacore.com/"
+SRC_URI="
+	http://mirrors.cdn.adacore.com/art/5b0819dfc7a447df26c27a68
+		-> ${MYP}-src.tar.gz
+	http://mirrors.cdn.adacore.com/art/5b0819dec7a447df26c27a40
+		-> xmlada-gpl-${PV}-src.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnat_2016 gnat_2017 +gnat_2018 gnat_2019"
+
+DEPEND="gnat_2016? ( dev-lang/gnat-gpl:4.9.4 )
+	gnat_2017? ( dev-lang/gnat-gpl:6.3.0 )
+	gnat_2018? ( dev-lang/gnat-gpl:7.3.1 )
+	gnat_2019? ( dev-lang/gnat-gpl:8.3.1 )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/${MYP}-src
+
+REQUIRED_USE="!gnat_2016 ^^ ( gnat_2017 gnat_2018 gnat_2019 )"
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
+
+src_prepare() {
+	if use gnat_2017; then
+		GCC_PV=6.3.0
+	elif use gnat_2018; then
+		GCC_PV=7.3.1
+	else
+		GCC_PV=8.3.1
+	fi
+	default
+	sed -i \
+		-e "s:@VER@:${GCC_PV}:g" \
+		share/gprconfig/compilers.xml \
+		share/gprconfig/gnat.xml \
+		share/gprconfig/c.xml \
+		share/gprconfig/linker.xml \
+		|| die
+	sed -i \
+		-e "s:@GNATBIND@:gnatbind-${GCC_PV}:g" \
+		src/gprlib.adb \
+		|| die
+}
+
+src_configure() {
+	emake prefix="${D}"usr setup
+}
+
+bin_progs="gprbuild gprconfig gprclean gprinstall gprname gprls"
+lib_progs="gprlib gprbind"
+
+src_compile() {
+	GCC=${CHOST}-gcc-${GCC_PV}
+	GNATMAKE=${CHOST}-gnatmake-${GCC_PV}
+	local xmlada_src="../xmlada-gpl-${PV}-src"
+	incflags="-Isrc -Igpr/src -I${xmlada_src}/sax -I${xmlada_src}/dom \
+		-I${xmlada_src}/schema -I${xmlada_src}/unicode \
+		-I${xmlada_src}/input_sources"
+	${GCC} -c ${CFLAGS} gpr/src/gpr_imports.c -o gpr_imports.o || die
+	for bin in ${bin_progs}; do
+		${GNATMAKE} -j$(makeopts_jobs) ${incflags} $ADAFLAGS ${bin}-main \
+			-o ${bin} -largs gpr_imports.o || die
+	done
+	for lib in $lib_progs; do
+		${GNATMAKE} -j$(makeopts_jobs) ${incflags} ${lib} $ADAFLAGS \
+			-largs gpr_imports.o || die
+	done
+}
+
+src_install() {
+	dobin ${bin_progs}
+	exeinto /usr/libexec/gprbuild
+	doexe ${lib_progs}
+	insinto /usr/share/gprconfig
+	doins share/gprconfig/*
+	insinto /usr/share/gpr
+	doins share/_default.gpr
+	einstalldocs
+}

dev-ada/gprbuild/metadata.xml

@@ -9,6 +9,7 @@
 		<flag name="gnat_2016">Compile with dev-lang/gnat-gpl-2016</flag>
 		<flag name="gnat_2017">Compile with dev-lang/gnat-gpl-2017</flag>
 		<flag name="gnat_2018">Compile with dev-lang/gnat-gpl-2018</flag>
+		<flag name="gnat_2019">Compile with dev-lang/gnat-gpl-2019</flag>
 	</use>
 	<longdescription lang="en">
 		GPRbuild is an advanced software tool designed to help automate the