app-crypt/xca: add 2.9.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>

app-crypt/xca/Manifest

@@ -1 +1,2 @@
 DIST xca-2.8.0.tar.gz 1955684 BLAKE2B 4ba352d023a3c7018cfb89cc6e8d9296c7a2664338ef4a3084339f96d32073065be7ec5d07e35cc9b91371e3d580872fa0d282ae10aa5bb36d0ffefa472c23d9 SHA512 14e880625f086d12cd39e55c1dc5703bdbc7cfcf683cf4706bb3fd0e2d9c2937194d3420f5e9a0a8f8fc22a24a56eaf67dc7c8eae5426e991f6737f0b6bb7a52
+DIST xca-2.9.0.tar.gz 1956908 BLAKE2B 96771a09039e2cfc14eae8bfc6686d3d43079c66872ade91ac2284c51903890cf68e43206c65e8d3bc674adf26af22bafe60f71f1996e210c0bc76c9601fb702 SHA512 7ccd12207b0f365fae371d5a7dbff5284446059aa096692e058f825ddd640d0a8e62e5f96b2c664e616b9716faacc4c3b482866f029692600150e2a787d90a53

app-crypt/xca/xca-2.9.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit cmake virtualx xdg-utils
+
+DESCRIPTION="A GUI to OpenSSL, RSA public keys, certificates, signing requests etc"
+HOMEPAGE="https://hohnstaedt.de/xca/"
+SRC_URI="https://github.com/chris2511/xca/archive/refs/tags/RELEASE.${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/xca-RELEASE.${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc"
+
+RDEPEND="
+	dev-libs/libltdl:0=
+	dev-qt/qtbase:6[sqlite,widgets]
+	dev-qt/qttools:6[assistant]
+	dev-libs/openssl:*
+	doc? ( app-text/linuxdoc-tools )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	doc? ( dev-python/sphinx dev-python/sphinxcontrib-htmlhelp dev-python/sphinxcontrib-qthelp )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.8.0-man-page.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DQTFIXEDVERSION=Qt6
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	virtx default
+}
+
+src_install() {
+	cmake_src_install
+
+	insinto /etc/xca
+	doins misc/*.txt
+
+	dosym xca /usr/bin/xca-console
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}