dev-python/zstandard: Bump to 0.18.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/zstandard/Manifest

@@ -1 +1,2 @@
+DIST python-zstandard-0.18.0.gh.tar.gz 678765 BLAKE2B 7a297e76d65c6f5adbb87cc615f474d58c66bc9ee4050eb10277b596f7efda9109de815188b6efe55beb7aa637ec4779359a573c87094661ae28a080c9619576 SHA512 d573da893e3a372143271c7d9dec15cd4e9dd7355d2069e283df8b3feadbf999dddcc0aa37a2831a370526b2b045497f46326dcf13d3680dd8ee624bca1e7666
 DIST zstandard-0.17.0.tar.gz 629456 BLAKE2B 2b19c017b6255eaa22037e633f1f1dea1322c21dda3f1129e9593c5782b6cf3dbba12003711f6192bfa474a918cbf1eae2b5dd21fbf78731b8dfc62e69a27048 SHA512 312aa02c7309fac64cf70ca901942118d4b3f12f27d20cc18dcaba5ce155ad81ea8d7657501a33a5fb6cdc8bcca11f91141ea9d6c3fc09c28a84d698b9050391

dev-python/zstandard/zstandard-0.18.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=python-zstandard-${PV}
+DESCRIPTION="Zstandard Bindings for Python"
+HOMEPAGE="
+	https://github.com/indygreg/python-zstandard/
+	https://pypi.org/project/zstandard/
+"
+SRC_URI="
+	https://github.com/indygreg/python-zstandard/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="
+	app-arch/zstd:=
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/cffi-1.14.0-r2:=[${PYTHON_USEDEP}]
+	' 'python*')
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# the C backend is repeatedly broken, so force CFFI instead
+	sed -e '/PYTHON_ZSTANDARD_IMPORT_POLICY/s:default:cffi:' \
+		-i zstandard/__init__.py || die
+	# unreliable, fails on x86
+	sed -e 's:test_estimated_compression_context_size:_&:' \
+		-i tests/test_data_structures.py || die
+	# unbundle zstd
+	: > zstd/zstdlib.c || die
+	# it does random preprocessing on that, so we can't use #include
+	cp "${ESYSROOT}/usr/include/zstd.h" zstd/zstd.h || die
+	sed -i -e '/include_dirs/a    libraries=["zstd"],' make_cffi.py || die
+
+	distutils-r1_src_prepare
+
+	DISTUTILS_ARGS=(
+		--no-c-backend
+	)
+}
+
+src_test() {
+	rm -r zstandard || die
+	distutils-r1_src_test
+}