dev-python/sphinxcontrib-openapi: new package, add 0.7.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/sphinxcontrib-openapi/Manifest

@@ -0,0 +1 @@
+DIST sphinxcontrib-openapi-0.7.0.tar.gz 193897 BLAKE2B c0f1c46c6e8c67ddf95d163a68f5e22e6f2dff6622a3c21651b301dc1266b53b088d1b882e5e3347fad6347b86392bc9428b56f537c1d2320e7d9cd113c478f7 SHA512 36a7b6473b43af8d6fe2cf1bf22fb90848343911f69414cd742b942ff2ea33ac5ffba79c516dbb076b87c2a6e7e44d6958796daf06c9245a7184bfb6fdb53569

dev-python/sphinxcontrib-openapi/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">sphinxcontrib-openapi</remote-id>
+		<remote-id type="github">sphinx-contrib/openapi</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/sphinxcontrib-openapi/sphinxcontrib-openapi-0.7.0.ebuild

@@ -0,0 +1,41 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="OpenAPI (fka Swagger) spec renderer for Sphinx"
+HOMEPAGE="https://pypi.org/project/sphinxcontrib-openapi/
+	https://github.com/sphinx-contrib/openapi"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	dev-python/namespace-sphinxcontrib[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-httpdomain[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/m2r[${PYTHON_USEDEP}]
+	dev-python/picobox[${PYTHON_USEDEP}]
+	dev-python/deepmerge[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${D}" -name '*.pth' -delete || die
+}