sci-libs/rtabmap: bump to 0.13.2

Package-Manager: Portage-2.3.7, Repoman-2.3.3

sci-libs/rtabmap/Manifest

@@ -1 +1,2 @@
 DIST rtabmap-0.13.0.tar.gz 19482027 SHA256 1986c6eb6176f4d4fdafadf9264d8a85e8c0c2fc8f3d036bff7398e15f08ca21 SHA512 4a0f4e1aee7949bd76fd07138fea4ec440c081acf4caf8f96c5bb7969c3c1601f07db54bcc26421b2a4aad067220d50c8176a04974228feef9ede7331992ed75 WHIRLPOOL 82427e00ba4535dbe1ed7b0fd6c2c1d2946a1f59b8f7b36ebd8c5679a543114910a860f2a8840f8a95bd5c4c06a6105ee322b4413d6be5671e61788cee4612ef
+DIST rtabmap-0.13.2.tar.gz 19488841 SHA256 857cf6a002ae3a499d385d883915fa87705461dab572d1ec92fc10ea3d45430b SHA512 ce80e55271e4b998c0ab11ad7d01c6a5b0df1be72057343ed0f4ffca9a2c95f946ea991c14d023772dee3bceee3ce97946207daf90a69eb6e450017c54495f2e WHIRLPOOL 58b9aba5f73288d1fcfec96776fc846724decdf18863415eafc4929a535334064bb2c8468a95d26de3f7b0807f8267077f13d90e6557b2273fd41e0473b3b74b

sci-libs/rtabmap/rtabmap-0.13.2.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/introlab/rtabmap"
+fi
+
+inherit ${SCM} cmake-utils multilib
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/introlab/rtabmap/archive/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+DESCRIPTION="Real-Time Appearance-Based Mapping (RGB-D Graph SLAM)"
+HOMEPAGE="http://introlab.github.io/rtabmap/"
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples ieee1394 openni2 qt5"
+
+RDEPEND="
+	media-libs/opencv:=[qt5(-)?]
+	sci-libs/pcl:=[openni,vtk]
+	sci-libs/vtk:=[qt5(-)?]
+	sys-libs/zlib
+	sci-libs/octomap:=
+	ieee1394? ( media-libs/libdc1394 )
+	openni2? ( dev-libs/OpenNI2 )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		"-DWITH_QT=$(usex qt5 ON OFF)"
+		"-DWITH_DC1394=$(usex ieee1394 ON OFF)"
+		"-DWITH_OPENNI2=$(usex openni2 ON OFF)"
+		"-DBUILD_EXAMPLES=$(usex examples ON OFF)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	# Needed since we force ros crawling to be done only in
+	# /usr/share/ros_packages/
+	insinto /usr/share/ros_packages/${PN}
+	doins "${ED}/usr/share/${PN}/package.xml"
+}