kde-apps/ark: 23.04.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/ark/Manifest

@@ -1,2 +1,3 @@
 DIST ark-22.12.3.tar.xz 2874976 BLAKE2B dbb3492717dc3ee5b249a97f5bad1e0319fcd8a2a47256f5589d6a81709bf0d94bd98d7f1a9a4ce2fc1fc43fb749af74e0e35a2914f08d1235c17d51af7b400b SHA512 7f723d9d7f58987f930809b01a7e812169933ac511069e8e181c17648f8b0654a16c8708eb432d0cce15d4d2c1796d0024cb5e21bc643fecacfe33a0055bf37f
 DIST ark-23.04.1.tar.xz 3010580 BLAKE2B 33fa43b14a11c61463e9ff5453f23aa7f0514251214aaba4774525a672c7c6645592f8af70e5264235de0888338088eac55607ba251fb5722d8376be4b5a4e08 SHA512 2b17a50901164a4e92f218247818266c72a7a4f909b3a28e21bb87455bebc42fc83097392f8e7346d19d870e2d19e5f8b184c0016034509956e32722397418ae
+DIST ark-23.04.2.tar.xz 3010608 BLAKE2B 07f2595864c95cd53d2e76687e30decc2600781d51b6bda76cc9a05a118e0994492b033392a453fe772e5768c4f50b9c43aa18ed177f7167c1310f3c25861717 SHA512 64e57cf420691c41905d78e565de593128422bd0238172cefe8937b393de41cabdb34fe8df24577d7564a67a2b98fdfb27bc1df4a5278ff642934dd5f4295049

kde-apps/ark/ark-23.04.2.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org optfeature
+
+DESCRIPTION="File archiver by KDE"
+HOMEPAGE="https://apps.kde.org/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="zip"
+
+RDEPEND="
+	>=app-arch/libarchive-3.5.3:=[bzip2,lzma]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.6.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	test? ( >=dev-libs/libzip-1.6.0:= )
+"
+# app-arch/rar is binary only
+BDEPEND="
+	sys-devel/gettext
+	elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package zip LibZip)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# bug 822177: may segfault or hang indefinitely
+		-E "(kerfuffle-addtoarchivetest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "rar archive creation/extraction" "app-arch/rar"
+		optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
+		optfeature "7-Zip archive support" "app-arch/p7zip"
+		optfeature "lrz archive support" "app-arch/lrzip"
+		optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
+	fi
+	ecm_pkg_postinst
+}