x11-libs/libdrm: Version bump to 2.4.111

Signed-off-by: Matt Turner <mattst88@gentoo.org>

x11-libs/libdrm/Manifest

@@ -1 +1,2 @@
 DIST libdrm-2.4.110.tar.xz 436372 BLAKE2B 0d5f8bfe47bdcc96ef7dbe3ecf2da0b21262bae4396fa1e73c0f728d970d041a9925082c4526bc71e00f110c2eb0ba94313d9a7c27a2d4676073fdbc3708c628 SHA512 52f92ef1fe4c218a1d7dba53ef43334dbfca80e3209afe59f3a32c4bf67473126534e990df07a931a12d46a3b997c21ef17c1c4d8a0c88d44d5c6c040e3b6be3
+DIST libdrm-2.4.111.tar.xz 447388 BLAKE2B bd1fe6a1af3dbdd542ea9d3b887121d917c11ef9c3c0074bbe5d18ffd15050e2df63c744aa5e559e7f8a1f1e9561d3b2ba8b9a45ad72d7c1e6393b7eae99cf54 SHA512 17e92e9e4ded8031ac222764bed7e9ff430a1a377f5e435f6b62b4a7f45cb4c4b769b3b79fbcba11512c1ac973abf8cdcca8e0b9659ae095e915d3d5efcf5516

x11-libs/libdrm/libdrm-2.4.111.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/drm.git"
+PYTHON_COMPAT=( python3_{8..11} )
+
+if [[ ${PV} = 9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+inherit ${GIT_ECLASS} python-any-r1 meson-multilib
+
+DESCRIPTION="X.Org libdrm library"
+HOMEPAGE="https://dri.freedesktop.org/ https://gitlab.freedesktop.org/mesa/drm"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://dri.freedesktop.org/libdrm/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+VIDEO_CARDS="amdgpu exynos freedreno intel nouveau omap radeon tegra vc4 vivante vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS} valgrind"
+RESTRICT="test" # see bug #236845
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	video_cards_intel? ( >=x11-libs/libpciaccess-0.13.1-r1:=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	valgrind? ( dev-util/valgrind )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/docutils[${PYTHON_USEDEP}]')"
+
+python_check_deps() {
+	has_version -b "dev-python/docutils[${PYTHON_USEDEP}]"
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		# Udev is only used by tests now.
+		-Dudev=false
+		-Dcairo-tests=false
+		$(meson_use video_cards_amdgpu amdgpu)
+		$(meson_use video_cards_exynos exynos)
+		$(meson_use video_cards_freedreno freedreno)
+		$(meson_use video_cards_intel intel)
+		$(meson_use video_cards_nouveau nouveau)
+		$(meson_use video_cards_omap omap)
+		$(meson_use video_cards_radeon radeon)
+		$(meson_use video_cards_tegra tegra)
+		$(meson_use video_cards_vc4 vc4)
+		$(meson_use video_cards_vivante etnaviv)
+		$(meson_use video_cards_vmware vmwgfx)
+		# valgrind installs its .pc file to the pkgconfig for the primary arch
+		-Dvalgrind=$(usex valgrind auto false)
+	)
+	meson_src_configure
+}