app-crypt/autofirma-bin: new package, add 1.9.0

Bug: https://bugs.gentoo.org/950344
Bug: https://bugs.gentoo.org/743802
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

app-crypt/autofirma-bin/Manifest

@@ -0,0 +1 @@
+DIST autofirma-bin-1.9.0.zip 66555836 BLAKE2B 351e732b4a2e5ec42148abda6af1159e517d6ee5a9156a2ccd22be9e044fd7159238e04c23e81effbca9fcbfa71db7e1766b5019b39df38a6841b2d9a8b33ada SHA512 785b48fc5a7e991ee221e0a1264be4bbb0a0c0f505ecdf3d2da4cca63fc4076028423027457a7f3d4642c4e78a077e472f692734089be81396188a5211bd1689

app-crypt/autofirma-bin/autofirma-bin-1.9.0.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit rpm xdg
+
+DESCRIPTION="Spanish government certificate request generator"
+HOMEPAGE="https://administracionelectronica.gob.es/ctt/verPestanaGeneral.htm?idIniciativa=clienteafirma
+	https://github.com/ctt-gob-es/clienteafirma"
+
+# Upstream blocks wget, so we need a fallback option
+SRC_URI="
+	https://estaticos.redsara.es/comunes/autofirma/$(ver_rs 1- /)/Autofirma_Linux_Fedora.zip -> ${P}.zip
+	https://dev.gentoo.org/~pacho/${PN}/${P}.zip
+"
+S="${WORKDIR}"
+
+LICENSE="|| ( GPL-2 EUPL-1.1 )"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/nss[utils]
+	virtual/jre:17
+"
+BDEPEND="app-arch/unzip"
+
+QA_PREBUILT="*"
+
+src_unpack() {
+	default
+	rpm_unpack ./${PN/-bin}-$(ver_cut 1-2)-1.noarch_FEDORA.rpm
+	rm -r "${S}/usr/share/licenses" || die
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	mv "${S}"/usr . || die
+
+	# Fix .desktop file
+	sed -i -e '/Version/d' \
+		"${ED}"/usr/share/applications/${PN/-bin}.desktop || die
+	sed -i -e 's/Utilities/X-Utilities/g' \
+		"${ED}"/usr/share/applications/${PN/-bin}.desktop || die
+	sed -i -e 's/Signature/X-Signature/g' \
+		"${ED}"/usr/share/applications/${PN/-bin}.desktop || die
+}

app-crypt/autofirma-bin/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>pacho@gentoo.org</email>
+		<name>Pacho Ramos</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">ctt-gob-es/clienteafirma</remote-id>
+	</upstream>
+</pkgmetadata>