xfce-base/xfce4-panel: bump to 4.13.4

Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Denis Dupeyron <calchan@gentoo.org>

xfce-base/xfce4-panel/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.12.2.tar.bz2 1167175 BLAKE2B 09d16c58bb2d78242069fc2191009af6bb737fd6571f7d9ceef4b2b2dc0f0be6fcdad17aa588f69573b9d7f62ca0c54ec712bd467ff793b6952ede733889136b SHA512 b455e28ecbd9e2fc152e1132a806307597157605fef19c61091fce90984b2eded2c0b691d1fa2475c218c9d0b12103e348e648a32d3e8d0aa9ca210b7ae36a9e
 DIST xfce4-panel-4.13.3.tar.bz2 1239212 BLAKE2B 8bab0c2f291874064ec8684ab8ada8177cca3f6ad163638bb57b02d0e0f77ed484ecb71bd9a4e54a63d75a572db260d6f92b755d413e1c6c111aef613ca2c2cd SHA512 99921ffc295b0e00689df50946ea326496c6fca68d6dfc6a563c0fb9e18bef1e537659963e3a0e6ee83756417565ac3531bc43e0e909dbb369068e4905bde045
+DIST xfce4-panel-4.13.4.tar.bz2 1261056 BLAKE2B e09c540fca10417e8f3340cacd3f35dded832b512c11e4c485b93120b331cd4a29bcf0df6dae787cb3fd65567a705dff69d95551b073e49b5fc4fc62f598eb0e SHA512 16a3680aa2ab7fa357ca9d477ea0e41ca159a2c626fe65454ccdca339bb501ff0979264f5a4ae4728e3c0efe24e193eb28e7b5d1e003fecad8ab36b8457203c8

xfce-base/xfce4-panel/xfce4-panel-4.13.4.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="introspection"
+
+RDEPEND=">=dev-libs/glib-2.24:=
+	>=x11-libs/cairo-1:=
+	>=x11-libs/gtk+-2.20:2=
+	>=x11-libs/gtk+-3.22:3=[introspection?]
+	x11-libs/libX11:=
+	x11-libs/libwnck:3=
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-0.5:=
+	>=xfce-base/libxfce4ui-4.13:=
+	>=xfce-base/libxfce4util-4.13:=[introspection?]
+	>=xfce-base/xfconf-4.13:=
+	introspection? ( dev-libs/gobject-introspection:= )"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+
+		# enable GTK+2 compatibility
+		--enable-gtk2
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}