net-mail/automx2: Bump to version 2021.6

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Ralph Seichter <gentoo@seichter.de>
Closes: https://github.com/gentoo/gentoo/pull/23351
Signed-off-by: Sam James <sam@gentoo.org>

net-mail/automx2/Manifest

@@ -1 +1,2 @@
 DIST automx2-2021.5.tar.gz 172317 BLAKE2B 501dea5561d780fed538676e41dac46da01bae24388f477afa66e1b27e8a271e48bd6bddc8f9a4e0f5e7b3eb9f58fca9a9b2adaf78de2f7cd2feacfc8f85c9a4 SHA512 00281f32df6b117690d9780b8a587907518e2485dc37450765c3f35acb92a27da73ecd4e35cd05e0a5307d179ba3edaa1dec80900a059c975589ae904456c565
+DIST automx2-2021.6.tar.gz 175423 BLAKE2B 26c83f0932b7a6b13b2c0f476a90bf1a3f134ab33e07b16a13034495c51b5d6ee744d7735352c7833c4a5a5c441dba003b68d4b2de95cb4e75aa7d0b726917d6 SHA512 0a2bc51f1ba70bf4e27f234e6a25f97eae5e4a841b93ade7baa2a87ffa485185220bd70779018d5e438ab04f4f6e9b9605be780efd1b803dd7133520fd4ef360

net-mail/automx2/automx2-2021.6.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Email client autoconfiguration service"
+HOMEPAGE="https://automx.org/"
+SRC_URI="https://github.com/rseichter/automx2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="acct-user/automx2"
+RDEPEND="
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-migrate[${PYTHON_USEDEP}]
+	dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+	dev-python/ldap3[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	sed -i -e "/('scripts'/d" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	export AUTOMX2_CONF="tests/unittest.conf"
+	${EPYTHON} -m unittest discover tests/ || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( ${S}/docs/*.adoc ${S}/contrib/*sample.conf )
+	local HTML_DOCS=( ${S}/docs/*.{html,svg} )
+	newconfd "${FILESDIR}/confd" "${PN}"
+	newinitd "${FILESDIR}/init-r1" "${PN}"
+	insinto /etc
+	newins "${FILESDIR}/conf" "${PN}.conf"
+	distutils-r1_python_install_all
+}