gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-11-08 18:27:07 -08:00
Code Issues Projects Releases Wiki Activity

kde-apps/okular: 24.05.1 version bump

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2024-06-13 18:49:45 +02:00
parent 703b2ecac7
commit 2218f7eaba
2 changed files with 100 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files
kde-apps/okular/Manifest
+1
View File
@@ -1,2 +1,3 @@
DIST okular-23.08.5.tar.xz 8515760 BLAKE2B ec8ddf33917cc092e23934cc184280bf69fd92e184f05a14a3b0ec3636f00a90e35ab7c5b05e6b4083a4a94fb3d8725aa7b71686d5fe1d8962c4678690670f29 SHA512 c9e8b430fa4a5486cee0587f9beb077b4e8b5476f00ed42c9369fbb195ad9733ed310e01ebefc3c08cf78a53a3e72eab44c42a236b3dcad7e02421a864331dd6
DIST okular-24.05.0.tar.xz 8017884 BLAKE2B a68fbe25602f1caafd0fc7a68cc82edb7baa41abe9799e0ec70caa9317688240d1f4280fe653e1480b075dbe13c3f3aa1c9113d79824b2379a61c9d4fd4f1813 SHA512 8c9200fb8c848613e3f115a3509403f8bd7a21d175a7c37d0838facb628553077d6651a7a4797e8432db4e94592e42bb44a65dcc0aa0773a4d5704dedc730ddd
DIST okular-24.05.1.tar.xz 8017872 BLAKE2B b1f6cdd726ea0375ab942d478609c9c0775aea472e3f8767c351c499108c1e9eb932bd613eb8a059fb753181c0902b909fba87d3d3c5d631b2229ab701455fc7 SHA512 43f1cbb9ec33e8c486179eff7641179346f92945205632278c6fcb1a263bb7b2cd2c91ab1b972d09151fb00106c5d78872273bf4fcf2a80ffc1942e30ac856df
kde-apps/okular/okular-24.05.1.ebuild
+99
View File
@@ -0,0 +1,99 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="forceoptional"
PVCUT=$(ver_cut 1-3)
KFMIN=6.3.0
QTMIN=6.6.2
inherit ecm gear.kde.org
DESCRIPTION="Universal document viewer based on KDE Frameworks"
HOMEPAGE="https://okular.kde.org https://apps.kde.org/okular/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64"
IUSE="crypt djvu epub markdown mobi +pdf phonon +postscript qml share speech +tiff"
# slot op: Uses Qt6::CorePrivate
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,widgets,xml]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=dev-qt/qtsvg-${QTMIN}:6
>=kde-apps/libkexiv2-${PVCUT}:6
>=kde-frameworks/karchive-${KFMIN}:6
>=kde-frameworks/kbookmarks-${KFMIN}:6
>=kde-frameworks/kcolorscheme-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/kpty-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/threadweaver-${KFMIN}:6
kde-plasma/plasma-activities:6
media-libs/freetype
sys-libs/zlib
crypt? ( >=kde-frameworks/kwallet-${KFMIN}:6 )
djvu? ( app-text/djvu )
epub? ( app-text/ebook-tools )
markdown? ( >=app-text/discount-2.2.7-r1:= )
mobi? ( >=kde-apps/kdegraphics-mobipocket-${PVCUT}:6 )
pdf? ( >=app-text/poppler-23.12.0[nss,qt6] )
phonon? ( >=media-libs/phonon-4.12.0[qt6] )
postscript? ( app-text/libspectre )
share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
speech? ( >=dev-qt/qtspeech-${QTMIN}:6 )
tiff? ( media-libs/tiff:= )
"
RDEPEND="${DEPEND}
>=kde-frameworks/kimageformats-${KFMIN}:6
qml? ( >=kde-frameworks/kirigami-${KFMIN}:6 )
"
PATCHES=(
"${FILESDIR}/${PN}-24.04.80-tests.patch" # bug 734138
"${FILESDIR}/${PN}-20.08.2-hide-mobile-app.patch" # avoid same-name entry
)
src_configure() {
local mycmakeargs=(
-DCMAKE_DISABLE_FIND_PACKAGE_LibZip=ON
-DFORCE_NOT_REQUIRED_DEPENDENCIES="KF6DocTools;LibZip;KF6Wallet;DjVuLibre;EPub;Discount;QMobipocket6;Poppler;LibSpectre;KF6Purpose;Qt6TextToSpeech;TIFF;"
-DOKULAR_UI=$(usex qml "both" "desktop")
$(cmake_use_find_package crypt KF6Wallet)
$(cmake_use_find_package djvu DjVuLibre)
$(cmake_use_find_package epub EPub)
$(cmake_use_find_package markdown Discount)
$(cmake_use_find_package mobi QMobipocket6)
$(cmake_use_find_package pdf Poppler)
$(cmake_use_find_package phonon Phonon4Qt6)
$(cmake_use_find_package postscript LibSpectre)
$(cmake_use_find_package share KF6Purpose)
$(cmake_use_find_package speech Qt6TextToSpeech)
$(cmake_use_find_package tiff TIFF)
)
ecm_src_configure
}
src_test() {
# mainshelltest hangs, bug #603116
# parttest hangs, bug #641728, annotationtoolbartest fails, KDE-Bug #429640
# signunsignedfieldtest fails, whatever. bug #852749
local myctestargs=(
-E "(mainshelltest|parttest|annotationtoolbartest|signunsignedfieldtest)"
)
ecm_src_test
}