dev-libs/libmanette: add 0.2.12

* Bumped to EAPI-8
* docs generation changed from gtk-doc to gi-docgen
* requires >=dev-libs/gobject-introspection-1.83.2 and >=dev-lang/vala-0.56.18 due to using `g-ir-scanner --doc-format`
* new dependency: dev-libs/hidapi

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>
Part-of: https://github.com/gentoo/gentoo/pull/42179
Closes: https://github.com/gentoo/gentoo/pull/42179
Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/libmanette/Manifest

@@ -1 +1,2 @@
+DIST libmanette-0.2.12.tar.xz 60952 BLAKE2B 63c40d7acebdbc90c4f1d0663ae9f17bdb78dd9968007181654d6bca81f1c9a7516b73d5afa0bd8dc31f8d843a62fd8a66e82f2880c0eb76974f01a1596872d5 SHA512 0118ce0d97a73df26c6ea66a343ca40ec7d026100a3dc1dbbd66d57f6a49b073c59321ee1dbff162b832fec846b0722dce17b5a7fd6a9d3288e61d2b8a0609c0
 DIST libmanette-0.2.7.tar.xz 43928 BLAKE2B 10978109c22defc1fa3361ef08d824ec5a67fda86b020504322fb86db0f7157617daf34db6ddaf0c2221ad9419b04cad07fad17bb6de103b198c7664cee12c4d SHA512 c3ebaba901731d3f106379befba1c4020aa32dcd224ced7f24aab37e547644080202dfcdd0e8cbd0cb6c864410f038e483502d357ab9842ae0f25e9570d120ef

dev-libs/libmanette/libmanette-0.2.12.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="Simple GObject game controller library"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libmanette"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc +introspection +udev +vala test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="vala? ( introspection ) doc? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.50:2
+	udev? ( dev-libs/libgudev[introspection?] )
+	dev-libs/libevdev
+	dev-libs/hidapi
+	introspection? ( >=dev-libs/gobject-introspection-1.83.2:= )
+"
+DEPEND="${RDEPEND}"
+# libmanette usage of `g-ir-scanner --doc-format` requires >=dev-lang/vala-0.56.18
+# See https://bugs.gentoo.org/952906
+BDEPEND="
+	doc? ( dev-util/gi-docgen )
+	vala? (
+		$(vala_depend)
+		>=dev-lang/vala-0.56.18
+	)
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddemos=false
+		$(meson_use test build-tests)
+		-Dinstall-tests=false
+		$(meson_use doc doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+		$(meson_feature udev gudev)
+	)
+	meson_src_configure
+}