mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
sys-process/htop: use release tarball
Closes: https://bugs.gentoo.org/849422 Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James
@@ -1,3 +1,4 @@
|
||||
DIST htop-3.1.2.tar.gz 387656 BLAKE2B a9682b6f3475fbae6ab7fd57330271190ec32267c5a8f2aac845cd18c566eaa9beed642c1e67fbc9606f120df600c27ed2ef0480a29ef304875a99898c1f10e4 SHA512 7e08b820042e480ca61137ff24b468804b49b95c1bbedaf82029dd79d29c2c541c5211284ec075692203788bbb868a9d4326ffd24c68419e22eec13ae5012700
|
||||
DIST htop-3.2.0.tar.gz 393712 BLAKE2B fff50fce1dd58d5738ca4a75a8b4078aa34e9544798c81bb18a2674823ab13a93ecec8c00d034704ecaab6a871efa2b021550dc1f0a03aa86f638c28e84f769e SHA512 174eaa7333fa60e40f67148560c53125e7aaf46a48e7f3ecfa2daa68553c94b3d076d03320afd479dcee07e739c0ff286a81b67cbc994782c33e798d3ed4605c
|
||||
DIST htop-3.2.1.tar.gz 397632 BLAKE2B 301bc421b3ff8136a70603c523dd719d38703288114712a6e178c1a348b1bc9b9d578cdf3cf8fe99a9bcd2d5721cd2a10caeeeb4614b24c4f20a8e103c37d236 SHA512 d7b76e28ee870ac572ba1d9606dec6f9475346a00e599ca15838017c97683f1fc1be40417b9c1e76128cacc8a60ff9ba88c6b237be1835d309f98329b25644fc
|
||||
DIST htop-3.2.1.tar.xz 406048 BLAKE2B 7addefca7de8f0867220e6415f4585f7e6ecf655d6245e4a8e120552ac738544fde1c2d8e24ce1139209caad23994316e8be9611f6ed0253d60547158d17ff24 SHA512 f412c10ebdec4fb026fb93a79a9b0b84612ad5a0d28e37f06713e6c895f70e92cbd09a8737d04f3d51102295d7a419eb2c3ec3907b96f553fda8ff3d1a2142b6
|
||||
|
||||
105
sys-process/htop/htop-3.2.1-r1.ebuild
Normal file
105
sys-process/htop/htop-3.2.1-r1.ebuild
Normal file
@@ -0,0 +1,105 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{8..11} )
|
||||
|
||||
inherit linux-info optfeature python-any-r1 xdg
|
||||
|
||||
DESCRIPTION="interactive process viewer"
|
||||
HOMEPAGE="https://htop.dev/ https://github.com/htop-dev/htop"
|
||||
if [[ ${PV} == *9999 ]] ; then
|
||||
EGIT_REPO_URI="https://github.com/htop-dev/htop.git"
|
||||
inherit autotools git-r3
|
||||
else
|
||||
SRC_URI="https://github.com/htop-dev/htop/releases/download/${PV}/${P}.tar.xz"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
|
||||
fi
|
||||
|
||||
S="${WORKDIR}/${P/_}"
|
||||
|
||||
LICENSE="BSD GPL-2+"
|
||||
SLOT="0"
|
||||
IUSE="caps debug delayacct hwloc lm-sensors llvm-libunwind openvz unicode unwind vserver"
|
||||
|
||||
RDEPEND="
|
||||
sys-libs/ncurses:=[unicode(+)?]
|
||||
hwloc? ( sys-apps/hwloc:= )
|
||||
unwind? (
|
||||
!llvm-libunwind? ( sys-libs/libunwind:= )
|
||||
llvm-libunwind? ( sys-libs/llvm-libunwind:= )
|
||||
)
|
||||
kernel_linux? (
|
||||
caps? ( sys-libs/libcap )
|
||||
delayacct? ( dev-libs/libnl:3 )
|
||||
lm-sensors? ( sys-apps/lm-sensors )
|
||||
)
|
||||
"
|
||||
DEPEND="${RDEPEND}"
|
||||
BDEPEND="${PYTHON_DEPS}
|
||||
virtual/pkgconfig"
|
||||
|
||||
DOCS=( ChangeLog README )
|
||||
|
||||
CONFIG_CHECK="~TASKSTATS ~TASK_XACCT ~TASK_IO_ACCOUNTING ~CGROUPS"
|
||||
|
||||
pkg_setup() {
|
||||
python-any-r1_pkg_setup
|
||||
linux-info_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
if [[ ${PV} == 9999 ]] ; then
|
||||
eautoreconf
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
if [[ ${CBUILD} != ${CHOST} ]] ; then
|
||||
# bug #328971
|
||||
export ac_cv_file__proc_{meminfo,stat}=yes
|
||||
fi
|
||||
|
||||
local myeconfargs=(
|
||||
--enable-unicode
|
||||
$(use_enable debug)
|
||||
$(use_enable hwloc)
|
||||
$(use_enable !hwloc affinity)
|
||||
$(use_enable openvz)
|
||||
$(use_enable unicode)
|
||||
$(use_enable unwind)
|
||||
$(use_enable vserver)
|
||||
)
|
||||
|
||||
if use kernel_linux ; then
|
||||
myeconfargs+=(
|
||||
$(use_enable caps capabilities)
|
||||
$(use_enable delayacct)
|
||||
$(use_enable lm-sensors sensors)
|
||||
)
|
||||
else
|
||||
if use kernel_Darwin ; then
|
||||
# Upstream default to checking but --enable-affinity
|
||||
# overrides this. Simplest to just disable on Darwin
|
||||
# given it works on BSD anyway.
|
||||
myeconfargs+=( --disable-affinity )
|
||||
fi
|
||||
|
||||
myeconfargs+=(
|
||||
--disable-capabilities
|
||||
--disable-delayacct
|
||||
--disable-sensors
|
||||
)
|
||||
fi
|
||||
|
||||
econf "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
optfeature "Viewing processes accessing certain files" sys-process/lsof
|
||||
}
|
||||
@@ -3,25 +3,26 @@
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{8..10} )
|
||||
PYTHON_COMPAT=( python3_{8..11} )
|
||||
|
||||
inherit autotools fcaps linux-info python-any-r1 xdg-utils
|
||||
inherit linux-info optfeature python-any-r1 xdg
|
||||
|
||||
DESCRIPTION="interactive process viewer"
|
||||
HOMEPAGE="https://htop.dev/ https://github.com/htop-dev/htop"
|
||||
if [[ ${PV} == *9999 ]] ; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/htop-dev/htop.git"
|
||||
inherit autotools git-r3
|
||||
else
|
||||
SRC_URI="https://github.com/htop-dev/${PN}/archive/${PV/_}.tar.gz -> ${P}.tar.gz"
|
||||
SRC_URI="https://github.com/htop-dev/htop/releases/download/${PV}/${P}.tar.xz"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
|
||||
fi
|
||||
|
||||
S="${WORKDIR}/${P/_}"
|
||||
|
||||
LICENSE="BSD GPL-2+"
|
||||
SLOT="0"
|
||||
IUSE="caps debug delayacct hwloc lm-sensors llvm-libunwind openvz unicode unwind vserver"
|
||||
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
RDEPEND="
|
||||
sys-libs/ncurses:=[unicode(+)?]
|
||||
hwloc? ( sys-apps/hwloc:= )
|
||||
@@ -35,21 +36,15 @@ RDEPEND="
|
||||
lm-sensors? ( sys-apps/lm-sensors )
|
||||
)
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
${PYTHON_DEPS}"
|
||||
DEPEND="${RDEPEND}"
|
||||
BDEPEND="${PYTHON_DEPS}
|
||||
virtual/pkgconfig"
|
||||
|
||||
DOCS=( ChangeLog README )
|
||||
|
||||
CONFIG_CHECK="~TASKSTATS ~TASK_XACCT ~TASK_IO_ACCOUNTING ~CGROUPS"
|
||||
|
||||
S="${WORKDIR}/${P/_}"
|
||||
|
||||
pkg_setup() {
|
||||
if ! has_version sys-process/lsof ; then
|
||||
ewarn "To use lsof features in htop (what processes are accessing"
|
||||
ewarn "what files), you must have sys-process/lsof installed."
|
||||
fi
|
||||
|
||||
python-any-r1_pkg_setup
|
||||
linux-info_pkg_setup
|
||||
}
|
||||
@@ -57,12 +52,15 @@ pkg_setup() {
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
eautoreconf
|
||||
if [[ ${PV} == 9999 ]] ; then
|
||||
eautoreconf
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
if [[ ${CBUILD} != ${CHOST} ]] ; then
|
||||
export ac_cv_file__proc_{meminfo,stat}=yes #328971
|
||||
# bug #328971
|
||||
export ac_cv_file__proc_{meminfo,stat}=yes
|
||||
fi
|
||||
|
||||
local myeconfargs=(
|
||||
@@ -97,17 +95,11 @@ src_configure() {
|
||||
)
|
||||
fi
|
||||
|
||||
econf ${myeconfargs[@]}
|
||||
econf "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_desktop_database_update
|
||||
xdg_icon_cache_update
|
||||
xdg_pkg_postinst
|
||||
|
||||
fcaps cap_sys_ptrace /usr/bin/${PN}
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_desktop_database_update
|
||||
xdg_icon_cache_update
|
||||
optfeature "Viewing processes accessing certain files" sys-process/lsof
|
||||
}
|
||||
|
||||
Reference in New Issue
Block a user