gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-01 23:28:08 -07:00
Code Issues Projects Releases Wiki Activity

kde-apps/kmix: drop 25.08.1

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2025-10-09 17:49:35 +02:00
parent c8ca0d7260
commit 20b9751aa1
2 changed files with 0 additions and 79 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
kde-apps/kmix/Manifest
View File

@@ -1,3 +1,2 @@
DIST kmix-25.04.3.tar.xz 1177372 BLAKE2B 8cd1ed26e5e8eb0304f0d8e96c236c82d68403e5ccd41d3531c210a24d1aa036af556c48322acf56a30ad4aeeb916a8cf8aa5b8ecc84c8e1f42e15ab53f783a7 SHA512 7489a3309c8558035134d9e8ec89999c5b1b2fed83e28f2aee29f063c9229a28f44c475129273ca46d54cde1372a097b362f83fd3b82ce705a692a43b7c0f1b1
DIST kmix-25.08.1.tar.xz 1178648 BLAKE2B 63834480f615d2b14bf626dda7d79152d25763e5d2757f11b88fda850ddc15f35a59e7c54a2a1e2a8f4d112e21c01f23f2a309c66a743074700738646cc35219 SHA512 47cdbd162b6c093c1b684c5080747dd24c0852a15fda2582cbb8c092bac765cdf36c21fb09ba470cb468f25ca5bc03a9ac0ffefa368c1ec6dd7bf4731c2433c8
DIST kmix-25.08.2.tar.xz 1178672 BLAKE2B f7a2ad1c54dbdbef69e957a0ef4e2ef68a3305fb57fb301c709fa33d6f0c37d9478832545733c95731081315e008d7106768aa913df6fdff3e913e9edc000ec5 SHA512 70db1d974e5bd4bb44e63ce1773b6cd4502cf64e247f8f9c7fb323a342cc5f5cc2596a65838bc5ecce8acdb5a9f53c710a132ddaa67299b3c5ba570f9402d157

78
kde-apps/kmix/kmix-25.08.1.ebuild
View File

@@ -1,78 +0,0 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="forceoptional"
ECM_TEST="false"
KFMIN=6.16.0
QTMIN=6.9.1
inherit ecm gear.kde.org xdg
DESCRIPTION="Volume control gui based on KDE Frameworks"
HOMEPAGE="https://apps.kde.org/kmix/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
IUSE="alsa pulseaudio"
# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets,xml]
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kglobalaccel-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
alsa? ( >=media-libs/alsa-lib-1.0.14a )
pulseaudio? (
media-libs/libcanberra
media-libs/libpulse
)
"
RDEPEND="${DEPEND}"
PATCHES=(
# TODO: upstream
"${FILESDIR}/${PN}-23.04.2-autostart_disable.patch"
# Pending: https://invent.kde.org/multimedia/kmix/-/merge_requests/29
"${FILESDIR}/${PN}-24.12.2-revert-kcm_pulseaudio-dep.patch"
# Regressed in: https://invent.kde.org/multimedia/kmix/-/merge_requests/32
"${FILESDIR}/${PN}-25.03.90-revert-sndio-automagic.patch"
)
src_configure() {
local mycmakeargs=(
# XXX: sndio is maybe automagic since 5075cc9502b2768471fd917671fd98bfe5b877cc
$(cmake_use_find_package alsa ALSA)
$(cmake_use_find_package pulseaudio Canberra)
$(cmake_use_find_package pulseaudio PulseAudio)
)
ecm_src_configure
}
pkg_postinst() {
if use pulseaudio && has_version kde-plasma/plasma-pa; then
elog "In KDE Plasma, kde-plasma/plasma-pa is the default audio volume handler,"
elog "therefore, autostart by default was disabled for KMix."
elog
elog "Should you prefer to still use kde-apps/kmix instead, do the following:"
elog " - In system tray, right click on [Show hidden items]"
elog " - Select [Configure System Tray]"
elog " - In [Entries], search for [Audio Volume] and set it to [Disabled]"
elog
fi
elog "KMix will be shown as [Volume Control] after manually starting it once"
elog "and will be autostarted after configuring such in KMix startup settings."
xdg_pkg_postinst
}