mail-client/geary: Version bump

Package-Manager: Portage-2.3.3, Repoman-2.3.1

mail-client/geary/Manifest

@@ -1,2 +1,3 @@
 DIST geary-0.11.1.tar.xz 958616 SHA256 6efc5e1a944ca1c1a991d50d558fbe46ed58763b3f8b7bcd451b15078a9b2eb2 SHA512 5dc50c2c004a48d1df6c17ba492f24a27c51fa1ab2ea01c77d633611783781e9714aeec9bd6dad58856675c3d10d8223d5c75800a32676d7425e896d8479e4ad WHIRLPOOL 3cf0efd34fb4a97a0fb99fe118d6b34d20489a3bae7cd967e833327650596bfa0d49464601dd9cc1ff7d43fd94ee21a4e28726ecdba5c42e9dded724d72e90ea
 DIST geary-0.11.2.tar.xz 961724 SHA256 5c9e20ecd53672a42e22a436b9d3b6b9e9bf81ddf77163414a1c55986f9b4631 SHA512 cbfb7461d3125c94e24a32c1cf6baad417d07ac274f1f1f1df4ef7f07b6c6b872a32a35e69bf33c6c6b8960ac4cf8135984ca33f4d4c8861e4c0a1f22525ba88 WHIRLPOOL 876611449868bd03ae26b4dde13c11c16ee8da7497016235a9e8cca10563bad793a5ae5c80147dfcb2e5c41be4f342d372172702de02880525ff3b797ca9a1bb
+DIST geary-0.11.3.tar.xz 964024 SHA256 419e9875c81d00e990aab61d419e64ca925928f046af88362d9029a7ba8c82e4 SHA512 dee389384b6bab25f939f0f40525670c27e3687cdfdfbc0c5632ccb2e9e189be3902aedb4fb37affb67c8b149e40ff78e41efbf8a754d76dcd405c8295be0d4b WHIRLPOOL 3314a7f4b87c5d9e52d9abaefb7b26f1b0713afaadb05f396da92f5dc842745e223f84f1aedad00eafe20e95def6836058175acdb1a5a96d3628f664a29be3ae

mail-client/geary/geary-0.11.3.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+# Keep cmake-utils at the end
+inherit gnome2 vala cmake-utils
+
+DESCRIPTION="A lightweight, easy-to-use, feature-rich email client"
+HOMEPAGE="https://wiki.gnome.org/Apps/Geary"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+DEPEND="
+	>=app-crypt/gcr-3.10.1:0=[gtk,introspection,vala]
+	app-crypt/libsecret
+	dev-db/sqlite:3
+	dev-libs/glib:2[dbus]
+	>=dev-libs/libgee-0.8.5:0.8=
+	dev-libs/libxml2:2
+	dev-libs/gmime:2.6
+	media-libs/libcanberra
+	>=net-libs/webkit-gtk-1.10.0:3=[introspection]
+	>=x11-libs/gtk+-3.10.0:3[introspection]
+	x11-libs/libnotify
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+	nls? ( virtual/libintl )
+"
+DEPEND="${DEPEND}
+	app-text/gnome-doc-utils
+	dev-util/desktop-file-utils
+	nls? ( sys-devel/gettext )
+	$(vala_depend)
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# https://bugzilla.gnome.org/show_bug.cgi?id=751556
+	# https://bugzilla.gnome.org/show_bug.cgi?id=772879 (recheck in
+	# 0.12)
+	eapply "${FILESDIR}"/${PN}-0.7.2-cflags.patch
+
+	# https://bugzilla.gnome.org/show_bug.cgi?id=751557
+	eapply "${FILESDIR}"/${PN}-0.5.3-vapigen.patch
+
+	# https://bugzilla.gnome.org/show_bug.cgi?id=751558
+	eapply "${FILESDIR}"/${PN}-0.6.0-desktopfile.patch
+
+	local i
+	if use nls ; then
+		if [[ -n "${LINGUAS+x}" ]] ; then
+			for i in $(cd po ; echo *.po) ; do
+				if ! has ${i%.po} ${LINGUAS} ; then
+					sed -i -e "/^${i%.po}$/d" po/LINGUAS || die
+				fi
+			done
+		fi
+	else
+		sed -i -e 's#add_subdirectory(po)##' CMakeLists.txt || die
+	fi
+
+	cmake-utils_src_prepare
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDESKTOP_UPDATE=OFF
+		-DNO_FATAL_WARNINGS=ON
+		-DGSETTINGS_COMPILE=OFF
+		-DICON_UPDATE=OFF
+		-DVALA_EXECUTABLE="${VALAC}"
+		-DWITH_UNITY=OFF
+		-DDESKTOP_VALIDATE=OFF
+	)
+
+	cmake-utils_src_configure
+}