dev-python/sphinxcontrib-websupport: Remove py3.10 (per sphinx-8.2)

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.7-r1.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_TESTED=( python3_{11..13} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" pypy3_11 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Sphinx websupport extension"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinxcontrib-websupport/
+	https://pypi.org/project/sphinxcontrib-websupport/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"
+
+RDEPEND="
+	dev-python/jinja2[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]
+"
+# avoid circular dependency with sphinx
+PDEPEND="
+	>=dev-python/sphinx-5[${PYTHON_USEDEP}]
+"
+# there are additional optional test deps on sqlalchemy and whoosh
+BDEPEND="
+	test? (
+		${PDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/sqlalchemy[${PYTHON_USEDEP}]
+			dev-python/whoosh[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest