gnome-extra/cinnamon-session: add 6.0.4

Signed-off-by: Eli Schwartz <eschwartz93@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

gnome-extra/cinnamon-session/Manifest

@@ -1,2 +1,3 @@
 DIST cinnamon-session-5.8.1.tar.gz 199477 BLAKE2B 9371089e3caa4765498c2fa3ab9e5de03d47a67bced8a1a14fec33d7aea3372950b1e8f7f88be825697c8a2899dc0812f6ec7c5fb008f4bf2f4b5bdc343c01cc SHA512 8a88834a639c74b227f0d666fa2bcb4c3f73859ff8de84a440e84af3f3343c41c47a896ccf0dc09cc7114b7c921e2f670aec7846c57ec92b8da3333be7955309
 DIST cinnamon-session-6.0.2.tar.gz 165188 BLAKE2B 077552f147a61d4615db8091411314560a12b5c40420381280e41a35395119ece15602f9c74bac3409b49d4363285a386555a787ced10dee5ca757d254ccb7ec SHA512 80e1c5b8654aad805424351c1a49cc3f68e52ddcf0606180fd5ee006607829f4f451c6bdd9be7e022a258041e8a6967faf0b16b8536a0a8982dcc805e35fd01a
+DIST cinnamon-session-6.0.4.tar.gz 165520 BLAKE2B fa608de433a4d47db102b1f11c716da8afeabd5772b7e957449297629e39bc215124acd2f0f94afe91763590ab92b06a3bce8dd1a6bad3997b9496b4114a36fa SHA512 cd8ac8579f9311f5234dad17fb32d40a1c58da2292734e58c4832d94a8b0687e4909f5886c2db0dab1e0c396f12c3495a8d966e76373ac26f3bd9795efcd1f1f

gnome-extra/cinnamon-session/cinnamon-session-6.0.4.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson gnome2-utils python-single-r1 xdg-utils
+
+DESCRIPTION="Cinnamon session manager"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-session"
+SRC_URI="https://github.com/linuxmint/cinnamon-session/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="systemd"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.37.3:2
+	>=gnome-extra/cinnamon-desktop-6.0:0=
+	media-libs/libcanberra[pulseaudio]
+	virtual/opengl
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3:3[introspection]
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango[X]
+	>=x11-libs/xapp-2.8.1[introspection]
+
+	systemd? (
+		>=sys-apps/systemd-183
+	)
+	!systemd? (
+		sys-auth/elogind[policykit]
+	)
+"
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/xtrans
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Fix bad systemd include
+	# https://github.com/linuxmint/cinnamon-session/pull/164
+	"${FILESDIR}/${PN}-6.0.0-fix-optional-systemd.patch"
+)
+
+src_prepare() {
+	default
+	python_fix_shebang data cinnamon-session-quit
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dipv6=true
+		-Dxtrans=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}