app-emacs/dired-hacks: new package; add 0.0.1_p20230621

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/dired-hacks/Manifest

@@ -0,0 +1 @@
+DIST dired-hacks-0.0.1_p20230621.tar.gz 70320 BLAKE2B 1f28f4f54c250b82c3897a42273337a0a1c1ccc2a0c46addcf55d30a2e5bc61211665860701a83379e9ae8252d389fde3c51b7cf8a8739e11b5aac2ff2447293 SHA512 c682149af031807fa3a9d64bbe7f78896af57a066d37809b6889a968162e5787e751520ebf975e7765f6b37f38a19a679b0c9123d8d0bb687086e18de803c848

app-emacs/dired-hacks/dired-hacks-0.0.1_p20230621.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp
+
+DESCRIPTION="Collection of useful dired additions for GNU Emacs"
+HOMEPAGE="https://github.com/Fuco1/dired-hacks/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Fuco1/${PN}.git"
+else
+	[[ ${PV} == *_p20230621 ]] && COMMIT=874449d6fc98aee565e1715ec18acec3c1c2cafb
+	SRC_URI="https://github.com/Fuco1/${PN}/archive/${COMMIT}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-${COMMIT}
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+RESTRICT="test"  # Tests fail.
+
+DOCS=( README.md )
+SITEFILE="50${PN}-gentoo.el"
+
+RDEPEND="
+	app-emacs/dash
+	app-emacs/eimp
+	app-emacs/f
+	app-emacs/s
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		app-emacs/assess
+		app-emacs/shut-up
+	)
+"
+
+elisp-enable-tests buttercup tests
+
+src_compile() {
+	elisp_src_compile
+	elisp-make-autoload-file
+}

app-emacs/dired-hacks/files/50dired-hacks-gentoo.el

@@ -0,0 +1,2 @@
+(add-to-list 'load-path "@SITELISP@")
+(load "dired-hacks-autoloads" nil t)

app-emacs/dired-hacks/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnu-emacs@gentoo.org</email>
+    <name>Gentoo GNU Emacs project</name>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://github.com/Fuco1/dired-hacks/issues/</bugs-to>
+    <remote-id type="github">Fuco1/dired-hacks</remote-id>
+  </upstream>
+</pkgmetadata>