www-client/vivaldi: Add version 7.0.3495.10

Signed-off-by: James Le Cuirot <chewi@gentoo.org>
This commit is contained in:
James Le Cuirot
2024-10-31 22:21:00 +00:00
parent 3948d682b4
commit 1ea21291e2
2 changed files with 229 additions and 0 deletions
+3
View File
@@ -1,6 +1,9 @@
DIST vivaldi-stable_6.9.3447.54-1_amd64.deb 113636280 BLAKE2B 34003d015b2e5e7e48665363fba8d4f7bdbf0892e1eb75ec456a080cf501d9b030d9418ef931619a6d75d317b656a232955170fbe82bdafbcb816d29cdf5976b SHA512 38da40e04a99f247550706390b1344419aef0e80b89f8f89a73a19ab0d8ea2e24e23ff27aef363e0d6fb16139b0d72df4bb52e07e5cdd38e657fa3ba136923ef
DIST vivaldi-stable_6.9.3447.54-1_arm64.deb 105165576 BLAKE2B 0e084d2b1c41075db8199dc8e29d094acadd59c8538d6b6dca424bc0a310833e10dc5dd845fc4f64097b71a7f654d9a1c5a9cebfee31e1c25058a83ef1128825 SHA512 51549841f84327e79770033989f1663d53ed1fea9410ad13592360e89eabf4d8451750424fe105b353e90564c44ed04281feb596198210b40c948687f9e3be7c
DIST vivaldi-stable_6.9.3447.54-1_armhf.deb 106209184 BLAKE2B f878e1d7583f5fa72ba1381111c7210a323a9a272790ebdd57472af4c30ec49d47d1210bf34c6bbab32b444c2357de6d8d2f6e31f4f92c55db2097341dd3e333 SHA512 2944f4ca6112292e93bd7c2b5c58f99dea7a1de63c482960da41a424c9e5797cc606628ec6351c61cd14a9eacce02d1132443b72e9f9dd10f89515f3a1a13223
DIST vivaldi-stable_7.0.3495.10-1_amd64.deb 120990972 BLAKE2B 55db6b2efd9a94cba4b016e739c89ce5a14ef0ae05ee65340c3a51e93482714716e7567941498108755e46128688417fe8793efee10eb9eafd10762d03518511 SHA512 99fb82df069daeebca6c6fc4b2ba2beabcbba6797bf838dda5dd91967c70f275b00a77fd1869345ad70253ac51fc559653c63639e0924c107256eea8113d2d7b
DIST vivaldi-stable_7.0.3495.10-1_arm64.deb 112797448 BLAKE2B 0736c29d059fabc5b677c88d2a6ef260c11aa9ca9eb40dcc1604a763254e26a3311af9c0349b090240873a0f1e15eef4aef5fff78f0923131eedd0b5cb04c1ab SHA512 b69eddab970e10ccdf9bcb31b8e91a2a349e8c9aae55becc3313152e71459aba022f55a378a9810703c64614b44e8f4c7d3de3a56ad1e4b10d50eab17b4b051b
DIST vivaldi-stable_7.0.3495.10-1_armhf.deb 114002332 BLAKE2B b0f9292943acdb99077a765f493a80974e8e8fce093c02f5785dd3b864cbc8acedf1c3a6d7dbc8455b937db6401becc49fd9aa5bd13bea5c17a57c23b601c36b SHA512 077d591eef251a574ce2c3ea880df510656fdf5911c771b24dd05fe4900ea499bd36ccdff7e6bebe7afdf5ac6f7c2d655df52ff5f66b7e08ff80cf09a1145c6c
DIST vivaldi-stable_7.0.3495.6-1_amd64.deb 120922504 BLAKE2B a45944233dd3adf7704c36357212807f29dfca5a76d8e4b28ebcdc32cf05bd16b2feaa12e51174076b00dc93da82e6f6d6c0cc7570bcf8699164d35436d4f063 SHA512 bd2c70c5f0bcbe6fd617d6f622975abdf4d07891425d54e7fade9aa395e9e6e6e115be6fd88d50d0c613188b133164838cc8e621f7aecdeb718aa44c824b05e3
DIST vivaldi-stable_7.0.3495.6-1_arm64.deb 112791276 BLAKE2B b7d94f3b3c66961fe87a0b56c8203d755b710bf7960f8a67e25beba7611d89bf820e335387fae8d6f52548188f04ec4b3c9faf06069a3ca78df6720181745b0b SHA512 963f4a14027e0d08c9b494769b00c6f6144243431afdd5270e46f5c05e8436ef81204a03940684553f1c93b92a1cf404e0717536784421f990442f8fec761692
DIST vivaldi-stable_7.0.3495.6-1_armhf.deb 113945752 BLAKE2B ccb27a951238fde74fad992447eaab169724b4b4a09125d436168904cf87ddd43fbb037e88f3a667e529d64b110384f397c6d7a8495d8c01df4751be28d01cb5 SHA512 d96bd6baa2606d17388308292ba4ea8447f5d4bc91cdf216c9f704d4283ceaa0d4a0fee216e33611e576211b590f6bb1a40e881f8117a35370754aff287ab0c7
@@ -0,0 +1,226 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CHROMIUM_VERSION="128"
CHROMIUM_LANGS="
af
am
ar
az
be
bg
bn
ca
ca-valencia
cs
da
de
de-CH
el
en-GB
en-US
eo
es
es-419
es-PE
et
eu
fa
fi
fil
fr
fy
gd
gl
gu
he
hi
hr
hu
hy
id
io
is
it
ja
jbo
ka
kab
kn
ko
lt
lv
mk
ml
mr
ms
nb
nl
nn
pa
pl
pt-BR
pt-PT
ro
ru
sc
sk
sl
sq
sr
sr-Latn
sv
sw
ta
te
th
tr
uk
ur
vi
zh-CN
zh-TW
"
inherit chromium-2 desktop linux-info toolchain-funcs unpacker xdg
VIVALDI_PN="${PN/%vivaldi/vivaldi-stable}"
VIVALDI_HOME="opt/${PN}"
DESCRIPTION="A browser for our friends"
HOMEPAGE="https://vivaldi.com/"
if [[ ${PV} = *_p* ]]; then
DEB_REV="${PV#*_p}"
else
DEB_REV=1
fi
VIVALDI_BASE_URI="https://downloads.vivaldi.com/${VIVALDI_PN#vivaldi-}/${VIVALDI_PN}_${PV%_p*}-${DEB_REV}_"
SRC_URI="
amd64? ( ${VIVALDI_BASE_URI}amd64.deb )
arm? ( ${VIVALDI_BASE_URI}armhf.deb )
arm64? ( ${VIVALDI_BASE_URI}arm64.deb )
"
S="${WORKDIR}"
LICENSE="Vivaldi"
SLOT="0"
KEYWORDS="-* ~amd64 ~arm ~arm64"
IUSE="ffmpeg-chromium gtk proprietary-codecs qt5 qt6 widevine"
RESTRICT="bindist mirror"
#REQUIRED_USE="ffmpeg-chromium? ( proprietary-codecs )"
RDEPEND="
>=app-accessibility/at-spi2-core-2.46.0:2
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
dev-libs/nss
media-libs/alsa-lib
media-libs/mesa[gbm(+)]
net-print/cups
sys-apps/dbus
x11-libs/cairo
x11-libs/libdrm
x11-libs/libX11
x11-libs/libxcb
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libxkbcommon
x11-libs/libXrandr
x11-libs/pango[X]
gtk? ( gui-libs/gtk:4 x11-libs/gtk+:3 )
proprietary-codecs? (
!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
)
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
)
qt6? ( dev-qt/qtbase:6[gui,widgets] )
widevine? ( www-plugins/chrome-binary-plugins )
"
QA_PREBUILT="*"
CONFIG_CHECK="~CPU_FREQ"
src_unpack() {
unpack_deb ${A}
}
src_prepare() {
# Rename docs directory to our needs.
mv usr/share/doc/{${VIVALDI_PN},${PF}}/ || die
# Decompress the docs.
gunzip usr/share/doc/${PF}/changelog.gz || die
# The appdata directory is deprecated.
mv usr/share/{appdata,metainfo}/ || die
# Remove cron job for updating from Debian repos.
rm etc/cron.daily/${PN} ${VIVALDI_HOME}/cron/${PN} || die
rmdir etc/{cron.daily/,} ${VIVALDI_HOME}/cron/ || die
# Remove scripts that will most likely break things.
rm -vf ${VIVALDI_HOME}/update-{ffmpeg,widevine} || die
pushd ${VIVALDI_HOME}/locales > /dev/null || die
rm ja-KS.pak || die # No flag for Kansai as not in IETF list.
rm kmr.pak || die # No flag for Kurmanji.
chromium_remove_language_paks
popd > /dev/null || die
if use proprietary-codecs; then
einfo Bundled $($(tc-getSTRINGS) ${VIVALDI_HOME}/lib/libffmpeg.so | grep -m1 "^FFmpeg version ")
rm ${VIVALDI_HOME}/lib/libffmpeg.so || die
rmdir ${VIVALDI_HOME}/lib || die
fi
if ! use qt5; then
rm ${VIVALDI_HOME}/libqt5_shim.so || die
fi
if ! use qt6; then
rm ${VIVALDI_HOME}/libqt6_shim.so || die
fi
eapply_user
}
src_install() {
mv */ "${D}" || die
dosym ../../${VIVALDI_HOME}/${PN} /usr/bin/${VIVALDI_PN}
fperms 4711 /${VIVALDI_HOME}/vivaldi-sandbox
local logo size
for logo in "${ED}"/${VIVALDI_HOME}/product_logo_*.png; do
size=${logo##*_}
size=${size%.*}
newicon -s "${size}" "${logo}" ${PN}.png
done
if use proprietary-codecs; then
dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
/${VIVALDI_HOME}/libffmpeg.so.$(ver_cut 1-2)
fi
if use widevine; then
dosym ../../usr/$(get_libdir)/chromium-browser/WidevineCdm \
/${VIVALDI_HOME}/WidevineCdm
else
rm "${ED}"/${VIVALDI_HOME}/WidevineCdm || die
fi
case ${PN} in
vivaldi) dosym ${VIVALDI_PN} /usr/bin/${PN} ;;
vivaldi-snapshot) dosym ${PN} /${VIVALDI_HOME}/vivaldi ;;
esac
}