dev-python/translate-toolkit: Bump to 3.9.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/translate-toolkit/Manifest

@@ -1 +1,2 @@
 DIST translate-3.8.6.gh.tar.gz 1158560 BLAKE2B 127083188e3f25551e1a55b4499fb2247e7fb7c751d813f6a78491ec2f1e457e0c18d3416cf05533d11e36201b36814054f4eaf94693d04351a0928a0347fa98 SHA512 271b34ac44835af2e50537ec5a6a5d4dff497fd3358fe53c92e800109a347206d544f71bee7181ec335736a462578913262ddfbb27d4bcef39f247338bc99134
+DIST translate-3.9.1.gh.tar.gz 1175717 BLAKE2B 4d41b3de15de1f1611f5fbe05448c21943a5be3756af7594bd18a1f2da1c231dd2697d62a074cd6fec078a5178fb1116e359c720aa585fdb982b3f17afad62db SHA512 d38912046d522f0910149cea9a620f4378978bdff1366372681fa143f23764cf7c4d287fbc8713169d56f5d95c7048cfd34ab0ec560ca6dafbd18b45284d75eb

dev-python/translate-toolkit/translate-toolkit-3.9.1.ebuild

@@ -0,0 +1,119 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="
+	https://github.com/translate/translate/
+	https://pypi.org/project/translate-toolkit/
+"
+SRC_URI="
+	https://github.com/translate/translate/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/Levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+# Technically, the test suite also has undeclared dependency
+# on dev-python/snapshottest but all the tests using it are broken
+# anyway, so we skip them.
+BDEPEND="
+	test? (
+		dev-python/phply[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
+	# correctly, so we need to reassemble all data files in a single directory
+	local -x XDG_DATA_HOME=${T}/share
+	cp -r translate/share "${T}/" || die
+	cp -r "${ESYSROOT}/usr/share"/gaupol "${XDG_DATA_HOME}"/ || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+		# all tests based on snapshottest are broken and I'm too tired
+		# to figure this out
+		translate/tools/test_pocount.py::test_cases
+		translate/tools/test_pocount.py::test_output
+		translate/tools/test_junitmsgfmt.py::test_output
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		translate/storage/test_fluent.py
+		# changes directory and does not change it back, sigh
+		tests/odf_xliff/test_odf_xliff.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /usr
+	doins -r translate/share
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+}