mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 09:07:26 -08:00
dev-python/autobahn: Bump to 25.11.1
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
parent
287115e8bd
commit
1e0217c3d6
@ -1,2 +1,3 @@
|
||||
DIST autobahn-24.4.2.tar.gz 482700 BLAKE2B e94026e0cfbb3a3ba2a494ac50e851ed1c35a842dd6b5ce2ac437a19fa0d30061d16b0965831ce57067d6682df256e5140d67e0e9b4d71cc1dbcc16287ffbed1 SHA512 2caffa9a49e3661e665a4e2641b96ff48581264654cb35ebc2e8a67620ce81bd330895bb12a098488676ab74c8275e601f45357840ca074c3c6a3d7247e563e9
|
||||
DIST autobahn-25.10.2.tar.gz 375689 BLAKE2B 6017b902a776d1f912facc488b0186cd53029c2e223920b92e06bb011d56b42279d2225af73ae561b6c21fc9b9509231761753a42146529baa19d30a03932bc1 SHA512 134a484c16392fe58b0acfae247cd783a1278c0b818c110b68e20428bffcc804dc99d449b1567fed976cf69823ce9269243e2cd968357ae9a23689ad0d7032b7
|
||||
DIST autobahn-25.11.1.tar.gz 447019 BLAKE2B 05c8e7c5d3dc4de5db032030815af43531243f5c8b345474669a5ce9064f61ad44f3703a33df3600070952a786193bba748c6c372e0e86d9aea4ce4a425881d1 SHA512 8960a76558e51900cffda20c97c070a7bd26d0dc3c9d21f6db03ca152d526e52a4070b25fad313f1c5aeda5fb398af2447a2913cd842fede4d591111bb8cef60
|
||||
|
||||
128
dev-python/autobahn/autobahn-25.11.1.ebuild
Normal file
128
dev-python/autobahn/autobahn-25.11.1.ebuild
Normal file
@ -0,0 +1,128 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_EXT=1
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( python3_{11..13} )
|
||||
|
||||
inherit distutils-r1 optfeature pypi
|
||||
|
||||
DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
|
||||
HOMEPAGE="
|
||||
https://github.com/crossbario/autobahn-python/
|
||||
https://pypi.org/project/autobahn/
|
||||
"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
|
||||
IUSE="+native-extensions test xbr"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
# The order of deps is based on their appearance in pyproject.toml
|
||||
# All extra deps should be included in test and in optfeature
|
||||
RDEPEND="
|
||||
>=dev-python/txaio-25.9.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/cryptography-3.4.6[${PYTHON_USEDEP}]
|
||||
>=dev-python/hyperlink-21.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/ujson-4.0.2[${PYTHON_USEDEP}]
|
||||
>=dev-python/cbor2-5.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/py-ubjson-0.16.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
|
||||
|
||||
>=dev-python/flatbuffers-22.12.06[${PYTHON_USEDEP}]
|
||||
|
||||
>=dev-python/zope-interface-5.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/twisted-24.3.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/attrs-20.3.0[${PYTHON_USEDEP}]
|
||||
|
||||
native-extensions? (
|
||||
$(python_gen_cond_dep '
|
||||
>=dev-python/cffi-1.14.5[${PYTHON_USEDEP}]
|
||||
' 'python*')
|
||||
)
|
||||
"
|
||||
BDEPEND="
|
||||
native-extensions? (
|
||||
$(python_gen_cond_dep '
|
||||
>=dev-python/cffi-1.14.5[${PYTHON_USEDEP}]
|
||||
' 'python*')
|
||||
)
|
||||
|
||||
test? (
|
||||
>=dev-python/wsaccel-0.6.3[${PYTHON_USEDEP}]
|
||||
>=app-arch/brotli-1.0.0[python,${PYTHON_USEDEP}]
|
||||
>=dev-python/pyopenssl-20.0.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/service-identity-18.1.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pynacl-1.4.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pytrie-0.4.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/qrcode-7.3.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/base58-2.1.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/ecdsa-0.19.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/argon2-cffi-20.1.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/passlib-1.7.4[${PYTHON_USEDEP}]
|
||||
)
|
||||
"
|
||||
|
||||
EPYTEST_PLUGINS=( pytest-{asyncio,aiohttp} )
|
||||
distutils_enable_tests pytest
|
||||
|
||||
python_prepare_all() {
|
||||
if use xbr ; then
|
||||
eerror "***************"
|
||||
eerror "Required xbr dependencies are incomplete in Gentoo."
|
||||
eerror "So this functionality will not yet work"
|
||||
eerror "Please file a bug if this feature is needed"
|
||||
eerror "***************"
|
||||
else
|
||||
# remove xbr components
|
||||
export AUTOBAHN_STRIP_XBR="True"
|
||||
fi
|
||||
|
||||
distutils-r1_python_prepare_all
|
||||
|
||||
# remove "vendored" flatbuffers that conflict with actual flatbuffers
|
||||
# https://github.com/crossbario/autobahn-python/issues/1782
|
||||
rm -rf flatbuffers || die
|
||||
|
||||
if ! use native-extensions; then
|
||||
export AUTOBAHN_USE_NVX=0
|
||||
fi
|
||||
}
|
||||
|
||||
python_test() {
|
||||
rm -rf autobahn || die
|
||||
|
||||
einfo "Testing all, cryptosign using twisted"
|
||||
local -x USE_TWISTED=true
|
||||
"${EPYTHON}" -m twisted.trial autobahn || die "Tests failed with ${EPYTHON}"
|
||||
unset USE_TWISTED
|
||||
|
||||
einfo "RE-testing cryptosign and component_aio using asyncio"
|
||||
local -x USE_ASYNCIO=true
|
||||
epytest --pyargs \
|
||||
autobahn.asyncio.test.test_aio_{raw,web}socket \
|
||||
autobahn.wamp.test.test_wamp_{cryptosign,component_aio}
|
||||
unset USE_ASYNCIO
|
||||
|
||||
rm -f twisted/plugins/dropin.cache || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
optfeature "C-based WebSocket acceleration" "dev-python/wsaccel"
|
||||
optfeature "non-standard WebSocket compression support" \
|
||||
"dev-python/python-snappy"
|
||||
optfeature "TLS transport encryption" \
|
||||
"dev-python/pyopenssl dev-python/pynacl dev-python/pytrie dev-python/qrcode dev-python/service-identity"
|
||||
optfeature "WAMP-SCRAM authentication" \
|
||||
"dev-python/cffi dev-python/argon2-cffi dev-python/passlib"
|
||||
optfeature "native SIMD acceleration" "dev-python/cffi"
|
||||
|
||||
python_foreach_impl twisted-regen-cache
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
python_foreach_impl twisted-regen-cache
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user