media-gfx/curtail: bump to 1.6.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

media-gfx/curtail/Manifest

@@ -1 +1,2 @@
 DIST curtail-1.3.1.tar.gz 176042 BLAKE2B 0757c3c3eed24fea8f1493021d30df40fd8c78dad3bfd7f63cfaa83f36d36f69c47ba4e41a53a7a4299d436fb978ae3fc31afa07b5a1c9d82a6400a17c104966 SHA512 47d1b3939eaeaa3d27c497318bc80d0b7cb1c2674d66ed17c8cc5e6206b3efce7867ff01542b40ee6a4b4127160f2baed084b5b99cf518f2438dcf53af425f89
+DIST curtail-1.6.0.tar.gz 169234 BLAKE2B 7da8423cb0c4c169b07a770dcd75cabcf34a5b57bfa2aec814ae23eb60e9b3b0638040bb8223d90a1ab052f802dc3d0374f630fc184f2ac394a5c288aafe38f7 SHA512 9f2cc35d606a8c3629c43fde63e4b636021ea58aeaeb81f39f2a3129f7c05cfcb519f7ef6be53788cd9c975babff2f3917dab652b4e33fe7b768a603281f60c3

media-gfx/curtail/curtail-1.6.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Image compressor, supporting PNG, JPEG and WebP"
+HOMEPAGE="https://github.com/Huluti/Curtail/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Huluti/${PN^}.git"
+else
+	SRC_URI="https://github.com/Huluti/${PN^}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}"/${P^}
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="test"  # Just desktop / schema / appstream file validation (fails).
+
+RDEPEND="
+	${PYTHON_DEPS}
+	gui-libs/gtk:4[introspection]
+	$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+"
+BDEPEND="
+	${RDEPEND}
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+"
+RDEPEND+="
+	media-gfx/jpegoptim
+	media-gfx/optipng
+	media-gfx/pngquant
+	media-libs/libwebp
+"
+
+DOCS=( CHANGELOG.md README.md )
+
+src_prepare() {
+	sed -i "s|@PYTHON@|${PYTHON}|" "${S}"/src/${PN}.in || die
+
+	default
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}