dev-python/typer: Bump to 0.25.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/typer/Manifest

@@ -1,2 +1,3 @@
 DIST typer-0.24.1.tar.gz 118613 BLAKE2B fc4821bb1a91e32e7fe2376bda33d5fc411288567b08b460d03aab2a8d6f2ed7ea3f1e32db20cfdeb28258904f5ce5b496ebe25faf9dc221dcfa7fb25c59652d SHA512 581511a2e0397be85023237161c5683e3ea8cf30208b5090fe4b037fb1d351f3e1e80e33bc0dcf6d116a71926561cfb560b631fffb38195afffcf9a9a1e71439
 DIST typer-0.24.2.tar.gz 119849 BLAKE2B baa49b38a5d813278cf1cd98b4a354582902e192dd6265b0905f473c998eeccf0a9f6b4fc07a700ab73eb75d1c37f36122c6b1730778c3a18f15ae6cf2dd0b50 SHA512 4e282e616c8ea57665493bb15bbe3e2a6388f974b602c879a16c14c7c07e55960d9808f4af50b78e79149bb3cb9dbd26da397078ebef8264ec7893ba74034014
+DIST typer-0.25.0.tar.gz 120150 BLAKE2B bfe49f17770c9bf404f2a093fb923a26512c2ee2cc5687e2802aa625392a804a20d836fa9790d2ff942348de8a16f28079e4e3d7b86ddbdd5b6735fef665653b SHA512 83cfa736b297adce314ae64d949097940d715e9766e55bce01f8fe41ed361106a09f53f3ad6d524cbd34c842b8a41b83c5d490be4cb24c5b1c9721d0ad12e42a

dev-python/typer/typer-0.25.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 shell-completion pypi
+
+DESCRIPTION="Build great CLIs. Easy to code. Based on Python type hints"
+HOMEPAGE="
+	https://typer.tiangolo.com/
+	https://github.com/fastapi/typer/
+	https://pypi.org/project/typer/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/annotated-doc-0.0.2[${PYTHON_USEDEP}]
+	>=dev-python/click-8.2.1[${PYTHON_USEDEP}]
+	>=dev-python/rich-13.8.0[${PYTHON_USEDEP}]
+	>=dev-python/shellingham-1.3.0[${PYTHON_USEDEP}]
+	cli? ( !dev-lang/erlang )
+"
+BDEPEND="
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	if ! use cli; then
+		sed -i -e '/typer\.cli/d' pyproject.toml || die
+	fi
+}
+
+python_test() {
+	# See scripts/tests.sh
+	local -x TERMINAL_WIDTH=3000
+	local -x _TYPER_FORCE_DISABLE_TERMINAL=1
+	local -x _TYPER_RUN_INSTALL_COMPLETION_TESTS=1
+
+	epytest
+}
+
+python_install() {
+	if use cli && [[ ! ${COMPLETIONS_INSTALLED} ]]; then
+		local -x _TYPER_COMPLETE_TEST_DISABLE_SHELL_DETECTION=1
+		newbashcomp - typer < <(typer --show-completion bash || die)
+		newzshcomp - typer < <(typer --show-completion zsh || die)
+		newfishcomp - typer < <(typer --show-completion fish || die)
+		COMPLETIONS_INSTALLED=1
+	fi
+
+	distutils-r1_python_install
+}