games-board/pysolfc: add 3.1.0

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

games-board/pysolfc/Manifest

@@ -1,3 +1,4 @@
 DIST PySolFC-3.0.0.tar.xz 33364860 BLAKE2B 964e0c7642d713f97c0655597ca893a6396d6c4968fcc9dc0c7487948bb5f94e349f70a7cb5b006760653719d6a51775f5e2944b48f84d45b5b3dda22be1b1e9 SHA512 f7c9bc6dff71047516979a6d9fb559c616d5d76c0b0a476564114f8b302788145599cc89cabbfbdc110a5a4eab6148bddb57a4847f40077ccbbe972f36b811b0
+DIST PySolFC-3.1.0.tar.xz 32697568 BLAKE2B 9c303b24b9d3bbb2f10d66146a0e848158bb1dfa155aeeacbad4169fbec18d8bfd908b086836bafae93ec52a96c2a973550577dfc46ac8510614965637a78721 SHA512 fa8ccc06a8813e9935a7d3034fca1cf8723b5457b8ee575cce202911c5cef265f2d0b297b279ceae398a142b9da56d95f5bdbf193df18cb5acb6b8f285420259
 DIST PySolFC-Cardsets--Minimal-3.0.0.tar.xz 25188212 BLAKE2B a047a151b5c4256cfb0300c6bc75713db9aab63e4e76ba99233a59f39a9a7017406320a0e3b874b72084b3bccd14ca303f7af9666652efee85cf39803ad8c43c SHA512 9d4bacd072b450b29b9f1bec4557121a3647c2f837aeb6e249f452cb886467c5e7ca36dd36a78ea69a5c9df6f30d5245e12681d9d02fc9da2ece09c25d77e787
 DIST PySolFC-Cardsets-3.0.tar.bz2 87075654 BLAKE2B 527463ba2abe22c553753f7cb8f6608867a3da01532461cd29b5cf007a49c242cbdbe82f50751283d17a46ecb15b263e324fbc1288b5c5eb3cc9bdc1cfc9b257 SHA512 4544bc8b890d0cd41d66bd513faf86c21455f4d0f154e567fd689917f2f3ca56fadf3ca9372bc80c5b1d5387aa4abfab7952e73024a3e41101112e716f80b762

games-board/pysolfc/pysolfc-3.1.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="tk"
+inherit distutils-r1 xdg
+
+MY_PN="PySolFC"
+MY_P="${MY_PN}-${PV}"
+PS_CARD_P="${MY_PN}-Cardsets-3.0"
+PS_CARD_MIN_P="${MY_PN}-Cardsets--Minimal-3.0.0"
+
+DESCRIPTION="Exciting collection of more than 1000 solitaire card games"
+HOMEPAGE="https://pysolfc.sourceforge.io/"
+SRC_URI="
+	https://downloads.sourceforge.net/pysolfc/${MY_P}.tar.xz
+	extra-cardsets? ( https://downloads.sourceforge.net/pysolfc/${PS_CARD_P}.tar.bz2 )
+	!extra-cardsets? ( https://downloads.sourceforge.net/pysolfc/${PS_CARD_MIN_P}.tar.xz )
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3+ GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="extra-cardsets minimal +sound"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/attrs[${PYTHON_USEDEP}]
+		dev-python/configobj[${PYTHON_USEDEP}]
+		dev-python/pysol-cards[${PYTHON_USEDEP}]
+		dev-python/random2[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		sound? ( dev-python/pygame[${PYTHON_USEDEP}] )
+		!minimal? ( dev-python/pillow[jpeg,tk,${PYTHON_USEDEP}] )
+	')
+	!minimal? ( dev-tcltk/tktable )
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	if use extra-cardsets; then
+		find ../${PS_CARD_P} -type d -name .thumbnails -exec rm -r {} + || die
+	fi
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS.md NEWS.asciidoc README.md )
+	distutils-r1_python_install_all
+
+	doman docs/pysol{,fc}.6
+
+	insinto /usr/share/${MY_PN}
+	doins -r ../$(usex extra-cardsets ${PS_CARD_P} ${PS_CARD_MIN_P})/.
+
+	# html files are used at runtime, keep at default location
+	dosym -r /usr/share/{${MY_PN},doc/${PF}}/html
+
+	# russian translation is not currently displaying right?
+	# (please if works fine for you and this should be reverted)
+	# https://forums.gentoo.org/viewtopic-t-1142910.html
+	rm -- "${ED}"/usr/share/locale/ru/LC_MESSAGES/pysol.mo || die
+}