media-libs/vulkan-loader: add 1.4.321.0

Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

media-libs/vulkan-loader/Manifest

@@ -1 +1,2 @@
 DIST vulkan-loader-1.4.313.0.tar.gz 1757076 BLAKE2B afa2ffadd85df1c31d27c942154275e967b3dda3afa233da6a38493aefbb0a38e2e92964eaf071c15ffc72205276b6fe2fd1558629ebef7cc6bcfa622290bb8d SHA512 70eee07ec9f15ac809117c2ba951ca88995c8241d5eb94faf20e884d94078f7a36d26b5064fc60f32ecf0e087b5c8150fda3f4848a2b5160afc499eb775e6ee8
+DIST vulkan-loader-1.4.321.0.tar.gz 1762904 BLAKE2B bfa61277180ab00aab3096d20825ee9e84e366e81c490db12f61ecaee7a427db5c992ad85f041c72e6ac5c98474f203a961d4860de8d37ab8523f16b1961ddae SHA512 154d5e58f929511134b352f81e4bddc4f4f9aa04524060235b87161b0ca55e640720bb1c8bc7e0e71c445e13c3eeef3c2b5124e900db4f8ceeb98d81725babbd

media-libs/vulkan-loader/vulkan-loader-1.4.321.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=Vulkan-Loader
+inherit flag-o-matic cmake-multilib toolchain-funcs
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/vulkan-sdk-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-vulkan-sdk-${PV}
+fi
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="layers wayland X"
+
+DEPEND="
+	~dev-util/vulkan-headers-${PV}
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-base/xorg-proto
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+PDEPEND="layers? ( media-libs/vulkan-layers[${MULTILIB_USEDEP}] )"
+
+multilib_src_configure() {
+	# Integrated clang assembler doesn't work with x86 - Bug #698164
+	if tc-is-clang && [[ ${ABI} == x86 ]]; then
+		append-cflags -fno-integrated-as
+	fi
+
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_TESTS=OFF
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	keepdir /etc/vulkan/icd.d
+
+	cmake_src_install
+}