media-video/smtube: 19.6.0 version bump

Package-Manager: Portage-2.3.67, Repoman-2.3.16
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

media-video/smtube/Manifest

@@ -1 +1,2 @@
 DIST smtube-17.5.0.tar.bz2 748559 BLAKE2B 41c5be3933b74b079136788c99cf3e073eab5903596f2e39f9451493e17338d39454a8956841452f37e56c0e6051720a02a9765f3165f4e7e4aa1d93caa1a59f SHA512 bda1d166fe03eb85e5a9971b0d5422ea3e72ea91293c4dd14cdb447788635971a1d9977fd2dda60bfcda68183511b5c6ca6b39a229960fbd4c7c5f125882140b
+DIST smtube-19.6.0.tar.bz2 748844 BLAKE2B 55e662fc85ec44f067cba037c28b26fbfe08439bafea294dfcd1c4187e8df9f1f066780dd80c765dc4e584ba5b3917d8982a46253039b6327a30ff9d842b9e0b SHA512 f61e432b8f99e34ddbd9415064eecf30c9a3a6731d646073253d63690cf531321a7a5038117db981d036d1abfdbd3150df21bc22c9ae75e32c63ade3a859ecef

media-video/smtube/smtube-19.6.0.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="bg cs da de en_GB en es eu fr gl he_IL hr hu it ja ko ms nn_NO pl pt_BR pt ru sq sr tr uk zh_CN zh_TW"
+PLOCALE_BACKUP="en"
+inherit desktop l10n qmake-utils
+
+DESCRIPTION="YouTube Browser for SMPlayer"
+HOMEPAGE="http://smplayer.sourceforge.net/smtube"
+SRC_URI="mirror://sourceforge/smtube/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtscript:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwidgets:5
+"
+RDEPEND="${DEPEND}
+	|| (
+		media-video/smplayer
+		media-video/mpv
+		media-video/mplayer
+		media-video/vlc
+		media-video/totem
+	)
+"
+
+gen_translation() {
+	"$(qt5_get_bindir)"/lrelease ${PN}_${1}.ts
+	eend $? || die "failed to generate $1 translation"
+}
+
+src_compile() {
+	eqmake5 src/${PN}.pro
+	emake
+
+	cd src/translations || die
+	l10n_for_each_locale_do gen_translation
+}
+
+install_locale() {
+	insinto /usr/share/${PN}/translations
+	doins src/translations/${PN}_${1}.qm
+	eend $? || die "failed to install $1 translation"
+}
+
+src_install() {
+	dobin ${PN}
+	domenu ${PN}.desktop
+	newicon icons/${PN}_64.png ${PN}.png
+	dodoc Changelog
+
+	l10n_for_each_locale_do install_locale
+}