net-im/mattermost-desktop-bin: add 5.1.1

Signed-off-by: Viorel Munteanu <ceamac.paragon@gmail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

net-im/mattermost-desktop-bin/Manifest

@@ -1,2 +1,4 @@
 DIST mattermost-desktop-5.1.0-linux-ia32.tar.gz 102235544 BLAKE2B f7427aa195ec3be706243ce1f1aeb2cbad594905f86b6493796de2ebb7fa161e06b910af9a285583018bad9709e6ce16ee5bc168f2d98f26534af3de3b753b41 SHA512 a94be8235c5c1927c89615297c7e82ff2d1bc61e3600133a5af262bc25b6b6a7c50b516d58c7a387f672510736572aacc0bd9a657e5d25351eea4df2dc8958fc
 DIST mattermost-desktop-5.1.0-linux-x64.tar.gz 102764810 BLAKE2B 7e555d70aa15b308cea637b7ad12a11a16a93cb80693157afbfcf782efff03458e880eabbbd52292e476159669a6ebd809197ba4b2f6154093515cb7f51b7e6e SHA512 5fb3abaf93cdb4e76ba29e56f1da800d665171ade8aa475ccc927f667d513db34db37ee2e1326e59584a38260d32e6c0420ac36822e6b22564d76391a44c7e18
+DIST mattermost-desktop-5.1.1-linux-ia32.tar.gz 102392038 BLAKE2B ad18b2c654e9d1b7d575a0e877ae8ac702d0e5b37c2654ff5b000404f25cf1a67995cc9a63ce833c7779285ed4a038aadc00d2e5dab9de1737142bc98d77f632 SHA512 57e1901d0d9c106e16a3ff7df332cfb0716c0e6b1bdf0dd447cd81059df628c445164079baa464751980583f4de12d704f46f3601df1823eab05cd83b850d73f
+DIST mattermost-desktop-5.1.1-linux-x64.tar.gz 102908239 BLAKE2B 34bb28894aa8a4dc5e2c9ea2ad601665db4a1a1eaf888f3eaeeabf01aedab07a51da0a3cb25e11bbf08b16e12a24af7e8d8dec308be3951d8d52953a0c9abd43 SHA512 576f41d0a5f7a6217c13594a7b5328442203d143b7ee54843167a38d0cdcb38d93732bcf3f42d6e329107917989f261483a303a2780f7639b0d91666d5a82c73

net-im/mattermost-desktop-bin/mattermost-desktop-bin-5.1.1.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN%-*}"
+MY_PV="${PV/_rc/-rc}"
+
+inherit desktop xdg
+
+DESCRIPTION="Mattermost Desktop application"
+HOMEPAGE="https://mattermost.com/"
+
+SRC_URI="
+	amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
+	x86?   ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-ia32.tar.gz )
+"
+
+LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2[X]
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3[X]
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+"
+
+QA_PREBUILT="
+	opt/mattermost-desktop/mattermost-desktop
+	opt/mattermost-desktop/libnode.so
+	opt/mattermost-desktop/libffmpeg.so
+	opt/mattermost-desktop/libGLESv2.so
+	opt/mattermost-desktop/libEGL.so
+	opt/mattermost-desktop/libvk_swiftshader.so
+"
+
+DOCS=(
+	NOTICE.txt
+)
+
+S="${WORKDIR}"
+
+src_install() {
+	if use amd64; then
+		cd "${WORKDIR}/mattermost-desktop-${MY_PV}-linux-x64" || die
+	elif use x86; then
+		cd "${WORKDIR}/mattermost-desktop-${MY_PV}-linux-ia32" || die
+	fi
+
+	newicon app_icon.png ${MY_PN}.png
+
+	insinto "/opt/${MY_PN}/locales"
+	doins locales/*.pak
+
+	insinto "/opt/${MY_PN}/resources"
+	doins resources/*.asar
+
+	insinto "/opt/${MY_PN}"
+	doins *.pak *.bin *.dat
+	exeinto "/opt/${MY_PN}"
+	doexe *.so "${MY_PN}"
+
+	dosym "../../opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
+
+	make_desktop_entry "${MY_PN}" Mattermost "${MY_PN}"
+
+	einstalldocs
+}